How Do I Close Any Open File

I want to be able to be able to close any open file. How do I do this?

Idea #1 = I've been puzzling over the Help article for Lock and Unlock statements. It would appear that it is possible to close any file in theory? I cant get it to work.

Idea #2 = If I could be certain that the current window is displaying the open filename (or if I could force this window to be the active window), I could use SendKeys to send Alt + F4 to close the file? (Not the best solution but if Idea #1 doesn't work...)



Below is what I've been playing around with.

Public Sub DevTestOpenPDF()
'/ open PDF. 
'/ If PDF is already open, close it and reopen (this is to ensure that we have full control & active focus on this file after Shell.Open)
    Dim strFullName As String
    Dim objShell As Object

    strFullName = fnstrFilePicker("PDF Document", ".PDF")

    If Not fnblnExistsFileFolder(strFullName) Then
        'prevents trying to open empty string or "False"
        Exit Sub
    End If

    If fnblnIsFileOpen(strFullName) Then

        MsgBox "ADD NEW CODE HERE - TO CLOSE FILE", vbInformation
        Debug.Assert False

        'make sure that the file is closed before continuing
        If fnblnIsFileOpen(strFullName) Then
            MsgBox "Code failed to close file. Goodbye", vbCritical
            Exit Sub
        End If
    End If
 
    'open file
    Set objShell = CreateObject("Shell.Application")
    objShell.Open (strFullName)


    'to add rest of code here


    Set objShell = Nothing
End Sub


Public Function fnblnExistsFileFolder(ByVal strFullName As String) As Boolean
'adapted from function written by Ken Puls (www.excelguru.ca)
    If Len(strFullName) > 0 Then
        On Error Resume Next
        fnblnExistsFileFolder = (Dir(strFullName, 31) <> vbNullString)
        On Error GoTo 0
    End If
End Function

Public Function fnstrFilePicker(Optional ByVal FileFilter1of2 As String, _
                                Optional ByVal FileFilter2of2 As String, _
                                Optional ByRef Title As String = "Open", _
                                Optional ByVal strInitialPath As String) As String
'TO IMPROVE THIS FUNCTION FOR ARGUMENTS OF MULTIPLE FILTERS OR MULTIPLE EXTS ON 1 FILTER

'To include multiple file types in the same filter, specify multiple filters in the second string and separate them with a semi-colon.
'Replaced omitted arguments with default values as per Help

    Dim strFilePath As String
    Dim strRestoreCurDir As String

    'change curdir if initial path provided
    If Not Len(strInitialPath) = 0 Then
        strRestoreCurDir = CurDir()
        Call SetCurDir(strInitialPath)
    End If

    'If either FileFilter arguments omitted then replace both with defaults
    If Len(FileFilter1of2) = 0 Or Len(FileFilter2of2) = 0 Then
        FileFilter1of2 = "All Files (*.*)"
        FileFilter2of2 = "*.*"
    End If

    'file extensions - ensure wildcard in place, add if not
    If Not Left$(FileFilter2of2, 2) = "*." Then
        Select Case Left$(FileFilter2of2, 1)
        Case "."
            'only missing wildcard
            FileFilter2of2 = "*" & FileFilter2of2
        Case Else
            'is missing wildcard and extension separator
            FileFilter2of2 = "*." & FileFilter2of2
        End Select
    End If

    'merge arguments to create filefilter string
    'FileFilter1of2 = FileFilter1of2 & " (" & FileFilter2of2 & "), " & FileFilter2of2
    FileFilter1of2 = FileFilter1of2 & ", " & FileFilter2of2

    strFilePath = Application.GetOpenFilename(FileFilter:=FileFilter1of2, Title:=Title, MultiSelect:=False)

    If Len(strFilePath) = 0 Then
        'user cancelled
        GoTo ExitProcedure
    End If

    fnstrFilePicker = strFilePath

ExitProcedure:
    Call SetCurDir(strRestoreCurDir)
End Function


Public Function fnblnIsFileOpen(ByVal strFullName As String) As Boolean
    Dim lngFF       As Long
    Dim lngErrNo    As Long

    On Error Resume Next
    lngFF = FreeFile()
    Open strFullName For Input Lock Read As #lngFF
    Close lngFF
    lngErrNo = Err.Number
    On Error GoTo 0

    fnblnIsFileOpen = (lngErrNo <> 0)
End Function

Kills a process based on it's title...

'// Add to a module
Option Explicit

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
    (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" _
    (ByVal hwnd As Long, ByRef lpdwProcessId As Long) As Long
Private Declare Function OpenProcess Lib "Kernel32" _
    (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, _
    ByVal dwProcessID As Long) As Long
Private Declare Function CloseHandle Lib "Kernel32" _
    (ByVal hObject As Long) As Long
Private Declare Function TerminateProcess Lib "Kernel32" _
    (ByVal hProcess As Long, ByVal uExitCode As Long) As Long

Private Const SYNCHRONIZE = &H100000
Private Const PROCESS_TERMINATE As Long = &H1

Public Sub KillApp(ByVal WindowTitle As String, Optional ByVal NoMessage As Boolean = False)

    ' Kills a running application based on the Window title
    '// Nededs an EXACT match...
    
    Dim lHwnd As Long
    Dim lProc As Long
    Dim lProcHnd As Long
    
    On Error GoTo Catch
    
    'WindowTitle = "Untitled - "
    
    ' Get the target's window handle.
    lHwnd = FindWindow(vbNullString, WindowTitle)
    If lHwnd = 0 Then
        If NoMessage Then
            Exit Sub
        Else
            Err.Raise 30000, , "Unable to find window handle of application to terminate"
        End If
    End If

    '// Get the process
    GetWindowThreadProcessId lHwnd, lProc
    If lProc = 0 Then
        If NoMessage Then
            Exit Sub
        Else
            Err.Raise 30001, , "Unable to get process ID of window handle"
        End If
    End If

    lProcHnd = OpenProcess(SYNCHRONIZE Or PROCESS_TERMINATE, 0, lProc)
    If lProcHnd = 0 Then
        If NoMessage Then
            Exit Sub
        Else
            Err.Raise 30002, , "Can't get process handle"
        End If
    End If

    '// Terminate Process
    If TerminateProcess(lProcHnd, 0&) = 0 Then
        If Not NoMessage Then
            Err.Raise 30003, , "Failed to terminate process"
        End If
    End If

    '// Close the process handle
    CloseHandle lProcHnd
    
    Exit Sub

Catch:
    MsgBox Err.Number & " - " & Err.Description, vbExclamation, "KillApp"
    
End Sub

Title needs to be an Exact match - there are alternatives to search for a Window based on a partial title, but just took the easiest option (I had the code already).

This kills a process, not just close the application - there will be no option to Save or any other dialogs that may be displayed by the application, before it is terminated.

Originally Posted by cytop

Kills a process based on it's title...

Interesting. +1

(I am looking to close an open file, not kill the whole program however I am open to alternative solutions on this thread)

Originally Posted by cytop

Title needs to be an Exact match - there are alternatives to search for a Window based on a partial title, but just took the easiest option (I had the code already).

An exact match may be a problem. I am primarily interested in solving the close file concept for PDFs. And depending on the system I am using, the default PDF software is Sumatra, FoxIt or Adobe Reader. Now the first one uses the filename as the window title. But the latter twos title is "[FileName] - [ProgramName]".

Originally Posted by cytop

This kills a process, not just close the application - there will be no option to Save or any other dialogs that may be displayed by the application, before it is terminated.

Understood. If I do end up going down the Kill Process route (instead of Close File) then I don't care about saving files before killing. Thanks for pointing that out though.

You can use WMI also for a brute force approach:

   Dim oProcess
   For Each oProcess In GetObject("winmgmts:").ExecQuery("Select Name from Win32_Process Where Name like 'ACRO%'")
      oProcess.Terminate
   Next oProcess

For a document specific approach, you'd want to loop through the open windows, get the caption and then probably send a WM_CLOSE message, or similar. Or if you know the full file name, perhaps simply GetObject.

Originally Posted by romperstomper

You can use WMI also for a brute force approach:

   Dim oProcess
   For Each oProcess In GetObject("winmgmts:").ExecQuery("Select Name from Win32_Process Where Name like 'ACRO%'")
      oProcess.Terminate
   Next oProcess

For a document specific approach, you'd want to loop through the open windows, get the caption and then probably send a WM_CLOSE message, or similar. Or if you know the full file name, perhaps simply GetObject.

Thanks for the suggestions Rory.

I don't see how the first two will work for me (1. requires the program process name - which I cant be programatically sure of unless I get stuck into registry detection of the process exe. 2. requires the name of the window title - which I cant be sure of - unless I assume that the open file will always contain the filename somewhere in the window title? and then loop through the titles looking for wildcard filename wildcard?)

I am looking into suggestion 3 now. This sounds like the best solution, I just need to solve the error messages on setting the object from the fullname. (Error 424 on trying to set object on open PDF) (UPDATE: I'm not the only one - http://www.vbaexpress.com/forum/show...ct-not-working )

Why do you need your code to close a PDF it didn't open?

Originally Posted by romperstomper

Why do you need your code to close a PDF it didn't open?

Hmmm...Good question.

I initially thought that if the PDF was already open, I would need to close it and reopen it in order to ensure that the code had full control and window focus before continuing.

However upon testing this morning, it seems that even if the file is already open, the rest of the code works just fine. In terms of window focus that is. I want to close the PDF once the code has finished - not essential I know.


UPDATE:
It may help if you can see what I want to use this close file code for? See attached. (And yes the attached is working for me but it assumes that the PDF software is Foxit. So it will fail on the other systems I work on)