If Item on Sheet Doesn't Exist in Specified Table, Add It To Table

Hello,

I have a Table on the Sheet CONTROL that contains Widgets.

There is another Sheet, called Received PT that contains a PivotTable of Widgets.

If the Widget does not exist on the CONTROL Sheet Table, but exists on the Received PT PivotTable, I would like to add the missing Widget to the CONTROL Sheet Table.

Any ideas? I am moderately stumped. and this would bring a long project to a close.

I have attached a workbook example.

One way:

Sub MatchUp()
    Dim rngCell               As Range
    Dim PT                    As PivotTable
    Dim lc                    As ListColumn
    Dim lo                    As ListObject
    Dim lr                    As ListRow

    Set PT = Sheets("Received PT").PivotTables(1)

    Set lo = Sheets("Control").ListObjects(1)
    Set lc = lo.ListColumns("REF#")

    For Each rngCell In PT.RowFields(1).DataRange.Cells
        If LenB(rngCell.Value) <> 0 Then
            If IsError(Application.Match(rngCell.Value, lc.DataBodyRange, 0)) Then
                Set lr = lo.ListRows.Add
                lr.Range(1).Value = rngCell.Value
            End If
        End If
    Next rngCell

End Sub

Romperstomper,

It works beautifully. Is there a way with this code, to have the quantity move over as well? I could do it with a VLOOKUP, but that sounds messier than the beauty you put above.

Thank you, again. Very much!

Romperstomper,

I was actually able to figure out the answer to my question...

   lr.Range(1).Value = rngCell.Value
   lr.Range(2).Value = rngCell.Offset(0, 1)