Macros help - when cell marked with "X"

New to macros here. Need to create macro for this:

If column "W" cells in worksheet called "ECN" contains "X or x" when I click a button called "Complete" the contents and formatting of that row need to cut and paste into a worksheet called "Closed" and then "Closed" worksheet needs to automatically sort least to greatest based on column "A" in "Closed" worksheet.

Thanks in Advance.

Good job on the explanation:

Sub Copy_Sort()
Dim ws1 As Worksheet:   Set ws1 = Sheets("ECN")
Dim ws2 As Worksheet:   Set ws2 = Sheets("Closed")
Dim i As Long

For i = ws1.Range("W" & Rows.Count).End(xlUp).Row To 2 Step -1
    If LCase(ws1.Range("W" & i)) = "x" Then
        ws1.Range("W" & i).EntireRow.Cut ws2.Range("A" & Rows.Count).End(3)(2)
        Rows(i).Delete
    End If
Next i

ws2.Sort.SortFields.Clear
ws2.Sort.SortFields.Add Key:=ws2.Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row), SortOn:=xlSortOnValues, Order:=xlAscending
With ws2.Sort
    .SetRange Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row).EntireRow
    .Apply
End With
    
End Sub

Originally Posted by stnkynts

Good job on the explanation:

Sub Copy_Sort()
Dim ws1 As Worksheet:   Set ws1 = Sheets("ECN")
Dim ws2 As Worksheet:   Set ws2 = Sheets("Closed")
Dim i As Long

For i = ws1.Range("W" & Rows.Count).End(xlUp).Row To 2 Step -1
    If LCase(ws1.Range("W" & i)) = "x" Then
        ws1.Range("W" & i).EntireRow.Cut ws2.Range("A" & Rows.Count).End(3)(2)
        Rows(i).Delete
    End If
Next i

ws2.Sort.SortFields.Clear
ws2.Sort.SortFields.Add Key:=ws2.Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row), SortOn:=xlSortOnValues, Order:=xlAscending
With ws2.Sort
    .SetRange Range("A2:A" & ws2.Range("A" & Rows.Count).End(xlUp).Row).EntireRow
    .Apply
End With
    
End Sub

Thanks so much!