Apply a hide/unhide macro to all selected tabs

Hi,

I would like to use the code of that thread( http://www.excelforum.com/excel-prog...ding-rows.html)

BUT is there a way to apply the below code to all selected tabs


Thank you


The code is ( thanks to Colin Legg)

    
    Dim rngCell As Range, rngToHide As Range, rngToCheck As Range
    Dim xlCalc As XlCalculation
    
    Application.ScreenUpdating = False
    xlCalc = Application.Calculation
    Application.Calculation = xlCalculationManual
    
    Set rngToCheck = ActiveSheet.Range("B2:B81")
    
    For Each rngCell In rngToCheck.Cells
        If rngCell.Value = " " Or rngCell.Value = 0 Then
            If rngToHide Is Nothing Then
                Set rngToHide = rngCell
            Else
                Set rngToHide = Union(rngToHide, rngCell)
            End If
        End If
    Next rngCell
     
    rngToCheck.Parent.Unprotect
    rngToCheck.EntireRow.Hidden = False
    
    If Not rngToHide Is Nothing Then
        rngToHide.EntireRow.Hidden = True
    End If
    
    rngToCheck.Parent.Protect
    Application.Calculation = xlCalc
    Application.ScreenUpdating = True

End Sub

Sub UnHideRows()
    
    Dim xlCalc As XlCalculation
    
    Application.ScreenUpdating = False
    xlCalc = Application.Calculation
    Application.Calculation = xlCalculationManual
    
    ActiveSheet.Unprotect
    ActiveSheet.Range("B2:B81").EntireRow.Hidden = False
    ActiveSheet.Protect
    
    Application.Calculation = xlCalc
    Application.ScreenUpdating = True

End Sub

Your UnhideRows sub as an example...

Sub UnHideRows()
    
   Dim xlCalc As XlCalculation
   Dim ws As Excel.Worksheet
    
   Application.ScreenUpdating = False
   xlCalc = Application.Calculation
   Application.Calculation = xlCalculationManual
    
   For Each ws In ThisWorkbook.Windows(1).SelectedSheets
    
      With ws
         .Unprotect
         .Range("B2:B81").EntireRow.Hidden = False
         .Protect
      End With
   Next
    
   Application.Calculation = xlCalc
   Application.ScreenUpdating = True

End Sub

Thank you but I am more interested in the Hide macro, I should miss somthing, but it doesn't work.