the code is finding repeated values but i need to search values from E column to D

Hello baig123,

Try this macro and let me know th results.

Sub FindAndColor()

    Dim Cell    As Variant
    Dim FndWhat As String
    Dim RegExp  As Object
    
        FndWhat = InputBox("Enter text!", "SEARCH_TEXT")
        
        Set RegExp = CreateObject("VBScript.RegExp")
        RegExp.IgnoreCase = True
        RegExp.Pattern = "\b" & FndWhat & "\b"
        
        For Each Cell In Selection
            Set Matches = RegExp.Execute(Cell)
            If Matches.Count > 0 Then
               Cell.Interior.ColorIndex = 6
               Cell.Interior.Pattern = xlSolid
            End If
        Next Cell
        
End Sub

No its dosent display any output

i have already specified words in column e what to find in column(d)

i need to run macro search in the column d

here searching for multiple values like

BELT
CAble
CONNECTOR
CLIP
CLAMP

Hello baig123,

Are you searching for full word matches or part word matches?

Do you want highlight the cell if any of these words are found?

Please provide accurate details about what you want to do.

yes i am finding both part words

i want to highlight with color mark yellow for cells

sorry for any confusion

Hello baig123,

It took quite a bit of time for to verify the macro was working correctly due to the large data set. A button has been added to the sheet to run the macro below.

Each cell in column "D" is checked for any of the words in column "E". The case is ignored and full words only are matched.

Sub FindAndColor()

    Dim Cell        As Variant
    Dim FndWhat     As String
    Dim RegExp      As Object
    Dim RngBeg      As Range
    Dim RngEnd      As Range
    Dim SearchWords As Variant
    Dim Word        As Variant
    
    
        Set RngBeg = Range("E2")
        Set RngEnd = Cells(Rows.Count, "E").End(xlUp)
        If RngEnd.Row < RngBeg.Row Then Exit Sub
        
        SearchWords = Range(RngBeg, RngEnd).Value
        
        Set RngBeg = Range("D2")
        Set RngEnd = Cells(Rows.Count, "D").End(xlUp)
        If RngEnd.Row < RngBeg.Row Then Exit Sub
        
        Set RegExp = CreateObject("VBScript.RegExp")
        RegExp.IgnoreCase = True
        
        Application.ScreenUpdating = False
        
            For Each Word In SearchWords
                RegExp.Pattern = "\b" & Word & "\b"
                For Each Cell In Range(RngBeg, RngEnd)
                    If RegExp.Execute(Cell).Count > 0 Then
                        Cell.Interior.ColorIndex = 6
                        Cell.Interior.Pattern = xlSolid
                    End If
                Next Cell
            Next Word
        
        Application.ScreenUpdating = True
        
End Sub

Hello baig123,

You're welcome.