Macro to create new tabs based off of a type and apply conditional formatting

I have a workbook with one tab and I am trying to figure out a macro that will do the following:

1-Take the data in Sheet1 and have the data broken into tabs containing the respective candy
-so a tab for bubble gum, candy bar, licorice, lollipop and stick candy
2-In each tab, have conditional formatting based on value in the Quality column
-red for a value between 0-25
-pink for a value between 26-50
-yellow for a value between 51-75
-green for a value between 76-100

For each tab, I still want each column that exists in Sheet1. I just want them broken out into new tabs.

Bit more than I originally thought it would be:

Sub RunMe()
Dim ws As Worksheet:    Set ws = Sheets("Sheet1")
Dim Sh As Worksheet
Dim rCell As Range
Dim lastrow As Long
Dim arrSh() As String
Dim bDim As Boolean
Dim i As Integer

Application.ScreenUpdating = False
bDim = False

lastrow = ws.Range("B" & Rows.Count).End(xlUp).Row
ws.Range("B1:B" & lastrow).AdvancedFilter xlFilterInPlace, , , True

'populate array with sheet names
For Each rCell In ws.Range("B2:B" & lastrow).SpecialCells(xlCellTypeVisible)
    If bDim = False Then
        ReDim arrSh(0 To 0) As String
        arrSh(0) = rCell.Value
        bDim = True
    Else
        ReDim Preserve arrSh(0 To UBound(arrSh) + 1) As String
        arrSh(UBound(arrSh)) = rCell.Value
    End If
Next rCell

ws.ShowAllData
ws.Range("A1").EntireColumn.EntireRow.Hidden = False

For i = LBound(arrSh) To UBound(arrSh)
    If Not Evaluate("ISREF('" & arrSh(i) & "'!A1)") Then
        Sheets.Add(After:=Sheets(Sheets.Count)).Name = arrSh(i)
        Set Sh = Sheets(arrSh(i))
            With ws
                .AutoFilterMode = False
                .Range("B1:B" & lastrow).AutoFilter 1, arrSh(i)
                .AutoFilter.Range.EntireRow.Copy Sh.Range("A1")
                .AutoFilterMode = False
            End With
            With Sh.Columns("C:C")
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, Formula1:="=0", Formula2:="=25"
                .FormatConditions(.FormatConditions.Count).SetFirstPriority
                .FormatConditions(1).Font.ColorIndex = 3
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, Formula1:="=26", Formula2:="=50"
                .FormatConditions(.FormatConditions.Count).SetFirstPriority
                .FormatConditions(1).Font.ColorIndex = 7
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, Formula1:="=51", Formula2:="=75"
                .FormatConditions(.FormatConditions.Count).SetFirstPriority
                .FormatConditions(1).Font.ColorIndex = 6
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlBetween, Formula1:="=76", Formula2:="=100"
                .FormatConditions(.FormatConditions.Count).SetFirstPriority
                .FormatConditions(1).Font.ColorIndex = 4
            End With
    End If
Next i

Erase arrSh
Application.ScreenUpdating = True

End Sub

That worked, thank you. I will mark as complete, but I am curious as to how the code changes if instead of font color, its the cell color that changes?

font change the text color; interior changes the cell color

Thank you, I have changed the macro to reflect the cell color to change and not the font. So now when I run the macro, the cell colors do change, but I think I a now missing something to tell the macro when to stop. For example, for lollipop including the title row, there are 25 rows, but the cells in C26 and onward show the color red.

Do I need to include something like "Interior.ColorIndex = xlNone" for rows that have no data?