I can use VBA to create a text box, how do I set the background colour?

Firstly I'm new to VBA, but trying to learn to make Excel more useful in work.

My company is using Excel 2003(!) and I'm trying to create custom buttons which add text boxes to selected cells - I want to create a series of buttons to create different coloured text boxes. Through lots of google searching, and some background reading I've managed to come up with the following code to create a text box the size of selected cells

Sub TextBox()    
     If TypeName(Selection) = "Range" Then
        With Selection
            ActiveSheet.Shapes.AddTextbox _
              msoTextOrientationHorizontal, .Left, _
              .Top, .Width, .Height
        End With
    End If
End Sub

Despite numerous tries, I can't figure out what code, or where to place it to set parameters such as font size, alignment and fill colour for the text box. Any help greatly appreciated.

Hello irf90,

Welcome to the Forum!

Here is a macro to change some the properties of the Text Box. There are more. To see them you need to view them in the Object Browser for the VB Editor.

Sub Macro1()

    Dim Msg As String
    Dim TB As Object
    
        On Error GoTo ErrHandler
        
        Set TB = ActiveSheet.TextBoxes(ActiveSheet.TextBoxes.Count)
        
        With TB
            .Interior.Color = RGB(255, 255, 0)
            .Font.Name = "Arial"
            .Font.Size = 8
            .Font.Bold = True
            .Font.Color = RGB(0, 0, 255)
            .Text = .Name
            .AutoSize = False
        End With
        
ErrHandler:
        If Err <> 0 Then
            Select Case Err.Number
                Case 0:     Exit Sub
                Case 1004:  Msg = "There are No Text Boxes on this Sheet."
            End Select
                
            If Msg <> "" Then MsgBox Msg, vbExclamation
        End If
        
End Sub

Thanks for your help Leith, problem solved!

I've been trying to incorporate that sort of code into my existing Macro but to no avail, and it's very frustrating - I'm trying to learn this but it didn't seem to be making much sense at the minute!

Hello irf90,

Trying changing

Dim TB As Object

To this

Dim TB As Excel.TextBox