Macro for different sheets

[coach.32]

I am trying to get a Macro to repeat a sort on the different sheets in my workbook.
The headers are all the same on each Worksheet, just with different data (segregated by Age Groups)
For example I need to sort Col's B1:B100, D1:D100 & then F1:F100
Through searching I have found the start of the code, but I have no idea how to complete it.

Dim ws As Worksheet
    For Each ws In Sheets
    ws.Activate

That's as far as I can go.
Could anyone please show me how to finish the code off? Thank you for any assistance you can offer.

[nathansav]

Record a macro doing one sheet, then loop, using your ws, instead of what ever will be recorded.

[JOHN H. DAVIS]

Maybe:

Sub coach_32()
Dim x As Integer
x = 2
Dim ws As Worksheet
    For Each ws In ActiveWorkbook.Worksheets
    ws.Activate
            For x = 2 To 6 Step 2
                 Columns(x).Select
                    Selection.Sort Key1:=Cells(1, x), Order1:=xlAscending, Header:=xlGuess, _
                    OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
                    DataOption1:=xlSortNormal
            Next x
    Next ws
End Sub

[HaHoBe]

Hi, coach.32,

no need to activate each sheet:

Sub foo()
Dim lngCol As Long
Dim ws As Worksheet
For Each ws In ActiveWorkbook.Worksheets
  For lngCol = 2 To 6 Step 2
    With ws
      .Range(.Cells(1, lngCol), .Cells(.Cells(Rows.Count, lngCol).End(xlUp).Row, lngCol)).Sort _
          Key1:=.Cells(1, lngCol), _
          Order1:=xlAscending, _
          Header:=xlGuess, _
          OrderCustom:=1, _
          MatchCase:=False, _
          Orientation:=xlTopToBottom, _
         DataOption1:=xlSortNormal
    End With
  Next lngCol
Next ws
End Sub

Ciao,
Holger