Macro to open up a .csv file inside each subfolder in a master folder

This would do it, but you need to call in from another sub to pass in the Extension, Directory path, and use TRUE for incSub (include Subfolders)

Sub LoopDirectoryExample(myPath As String, fileExtension As String,incSub As Boolean)

'FILE SYSTEM OBJECTS REQUIRE:
' While you are in the Visual Basic IDE, go to the Tools Menu > References
' Add a reference to the Microsoft Scripting Runtime library
'
    Dim fso As FileSystemObject
    Dim fld As Folder, subfld As Folder
    Dim fil As File
    Dim N As Long
    
     'initialize'
        Set fso = New FileSystemObject
        Set fld = fso.GetFolder(myPath)
        
    'place each file name in the array'
        For Each fil In fld.Files
            If UCase(fil.Name) Like "*." & UCase(fileExtension) Then

            '
            'DO YOUR THING TO THE FILES HERE
            '

            End If
        Next fil
        
    'pass in the subfolders if incSub is passed  in as "True"
    If incSub Then
            For Each subfld In fld.SubFolders
                Call LoopDirectoryExample(myPath & "\" & subfld.Name, fileExtension, True)
            Next subfld
    End If
End Sub

The portion in red just calls the sub routine again, for each subfolder (it's iterative, it will snake through sub folders within sub folders... within sub folders....)

The workbook could be passed into either routine - this structure just loops through and doesn't reference any workbooks yet. Be careful how you do that in the "DO YOUR THING TO THE FILE HERE" section.

*SORRY FOR DUPLICATE POST* computer was lagging

Here's what I would suggest. Add another parameter to the loop routine to allow you to pass in a workbook variable (byRef).

Then, in the main routine that will call the loop routine, SET the workbook as needed. After that, you can refer to that workbook by variable name SomeWorkbook in the Loop routine - no matter which iteration.

Having only one subfolder won't be any problem - the code can just handle as many as needed. The "For Each" style of loop is designed to loop over a "collection" (in this case, a collection of subfolders for any folder) and is by design flexible enough to handle 0,1,2,3.... members in the collection.

BTW, I didn't make these edits within the IDE so watch for typos (always use "Option Explicit" IMO)

Sub Driver()
  DIM targetBook as workbook
  Set target = thisWorkbook 'if you are calling the code from the workbook you would like to add data to.
  CALL listDirectoryExample(byRef targetbook,"MyPath","csv",TRUE)
End Sub

Sub LoopDirectoryExample(byRef SomeWorkbook as workbook,myPath As String, fileExtension As String,incSub As Boolean)

'FILE SYSTEM OBJECTS REQUIRE:
' While you are in the Visual Basic IDE, go to the Tools Menu > References
' Add a reference to the Microsoft Scripting Runtime library
'
    Dim fso As FileSystemObject
    Dim fld As Folder, subfld As Folder
    Dim fil As File
    Dim N As Long
    
     'initialize'
        Set fso = New FileSystemObject
        Set fld = fso.GetFolder(myPath)
        
    'place each file name in the array'
        For Each fil In fld.Files
            If UCase(fil.Name) Like "*." & UCase(fileExtension) Then

            '
            'DO YOUR THING TO THE FILES HERE
            'Use SomeWorkbook to point to the right file :)

            End If
        Next fil
        
    'pass in the subfolders if incSub is passed  in as "True"
    If incSub Then
            For Each subfld In fld.SubFolders
                Call LoopDirectoryExample(someWorkbook, myPath & "\" & subfld.Name, fileExtension, True)
            Next subfld
    End If
End Sub

AHHHH! i should have typed it into the IDE.

That shouldn't be there (it only needs to appear below, in the LoopDirectoryExample definition of parameters)

Take that "ByRef" out!

Sub Driver()
  DIM targetBook as workbook
  Set target = thisWorkbook 'if you are calling the code from the workbook you would like to add data to.
  CALL listDirectoryExample(targetbook,"MyPath","csv",TRUE)
End Sub

Awesome it compiled! Many thanks.

The mechanisim is working perfectly.

However one quick problem:
The main goal is to open the csv file and paste contents into the target (main) WB on separate sheets. I did this by tracking the sheet index. I made a variable called sheet_index which I added +1 to everytime through the loop, this told the macro to paste the data onto the next sheet, or create a new sheet and paste depending on how many there were in the work book. NOW I can't use that method it seems. Below I have posted a shortened version of the main code. Currently, it just copies everything onto the same sheet...

Sub WLDO_Driver()

Dim targetBook As Workbook
Set targetBook = ActiveWorkbook
Dim i As Integer

'creates summary sheet in target WB
targetBook.Activate
Sheets.Add.Name = "SUMMARY"

Call LoopThroughDirectory(targetBook, "C:\Users\E1TCH02\Desktop\Input", "csv", True)

'creates chart
targetBook.Activate
Sheets("SUMMARY").Select
 Range("D2").Select
    ActiveSheet.Shapes.AddChart.Select
    With ActiveChart
      .ChartType = xlLine
      .SeriesCollection.NewSeries
      .SeriesCollection(1).Values = Sheets("SUMMARY").Range("a1", ActiveSheet.Range("a1").End(xlDown))
      .Axes(xlCategory).Select
    End With
    Selection.Delete

targetBook.Save

End Sub

Sub LoopThroughDirectory(ByRef SomeWorkbook As Workbook, myPath As String, fileExtension As String, incSub As Boolean)
    Dim fso As FileSystemObject
    Dim fld As Folder, subfld As Folder
    Dim fil As File
    Dim N As Long
    Dim sheet_index As Integer
    sheet_index = 1
    
     'initialize'
        Set fso = New FileSystemObject
        Set fld = fso.GetFolder(myPath)
        
    'place each file name in the array'
        For Each fil In fld.Files
            If UCase(fil.Name) Like "*." & UCase(fileExtension) Then
                Application.DisplayAlerts = False
                Set WB = Workbooks.Open(fil.Path)
    
                'copy results from the just opened wb
                WB.Worksheets(1).Select
                Range("a1:s2200").Select
                Selection.Copy
                WB.Close
                
                'go to main wb and paste data
                SomeWorkbook.Activate
                If sheet_index <= 4 Then
                    Sheets(sheet_index).Select
                    ActiveSheet.Paste
                Else
                    Sheets.Add
                    ActiveSheet.Paste
                End If                
                
    'I adjust the newly pasted data
        
    
'    'take wanted information from each sheet and paste onto summary sheet
    Range("G11:H12").Select
    Selection.Copy
    Sheets("SUMMARY").Select

    If Range("a1").Value = "" Or Range("a2").Value = 0 Then
       Range("a1").Select
    Else
       Range("a1").End(xlDown).Select
       ActiveCell.Offset(rowOffset:=1, columnOffset:=0).Select
    End If

    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    Columns("A:A").EntireColumn.AutoFit
'
    'save main workbook
    SomeWorkbook.Activate
    SomeWorkbook.Save

    End If
    
    sheet_index = sheet_index + 1    
  Next fil
        
    'pass in the subfolders if incSub is passed  in as "True"
    If incSub Then
            For Each subfld In fld.SubFolders
                Call LoopThroughDirectory(SomeWorkbook, myPath & "\" & subfld.Name, fileExtension, True)
            Next subfld
    End If
End Sub

Try it without the index - just add a new sheet every time. It's a good habit to use Option Explicit and always introduce variables used in a sub at the top with a DIM statement (like your WB).

Also, instead of just referencing "sheets()" or "range()" it's a good idea to qualify everything. So, instead of a sheets.add (which you then refer to later) I would use "Set NewSheet = WorkbookVariable.add"

When you fully qualify, you also don't have to worry about what's active or not -- all those .select or .activate statements can be trimmed out

Also, your code to copy then paste can be altered to "equate values of same-sized ranges".

Option Explicit

Sub WLDO_Driver()

Dim targetBook As Workbook
Dim i As Integer
Dim summarySheet As Worksheet

'creates summary sheet in target WB
Set targetBook = ActiveWorkbook
Set summarySheet = targetBook.Worksheets.Add
    summarySheet.Name = "SUMMARY"

Call LoopThroughDirectory(targetBook, "C:\Users\E1TCH02\Desktop\Input", "csv", True)

'creates chart
 targetBook.Activate
 Sheets("SUMMARY").Select
 Range("D2").Select
    ActiveSheet.Shapes.AddChart.Select
    With ActiveChart
      .ChartType = xlLine
      .SeriesCollection.NewSeries
      .SeriesCollection(1).Values = Sheets("SUMMARY").Range("a1", ActiveSheet.Range("a1").End(xlDown))
      .Axes(xlCategory).Select
    End With
    Selection.Delete

targetBook.Save

End Sub

Sub LoopThroughDirectory(ByRef SomeWorkbook As Workbook, myPath As String, fileExtension As String, incSub As Boolean)
    Dim fso As FileSystemObject
    Dim fld As Folder, subfld As Folder
    Dim fil As File
    Dim N As Long
    Dim sheet_index As Integer
    Dim WB As Workbook
    Dim newSheet As Worksheet
    
    sheet_index = 1
    
     'initialize'
        Set fso = New FileSystemObject
        Set fld = fso.GetFolder(myPath)
        
    'place each file name in the array'
        For Each fil In fld.Files
            If UCase(fil.Name) Like "*." & UCase(fileExtension) Then
                Application.DisplayAlerts = False
                Set WB = Workbooks.Open(fil.Path)
    
                'copy results from the just opened wb
                    Set newSheet = SomeWorkbook.Worksheets.Add
                    newSheet.Range("A1:S2200").Value = _
                        WB.Worksheets(1).Range("a1:s2200").Value
                    
                    targetBook.Worksheets("SUMMARY").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Resize(2, 2).Value = _
                        newSheet.Range("G11:H12").Value
              
            'save main workbook
                    SomeWorkbook.Save

            End If 'UCase(fil.Name) Like "*." & UCase(fileExtension)
    
        Next fil
        
    'pass in the subfolders if incSub is passed  in as "True"
    If incSub Then
            For Each subfld In fld.SubFolders
                Call LoopThroughDirectory(SomeWorkbook, myPath & "\" & subfld.Name, fileExtension, True)
            Next subfld
    End If
End Sub

No problem, we've all been there. My only programing experience prior to working in excel was Turbo Pascal, and Python / C also

Please mark your original post as "Solved"