Textbox loop check to validate entry

You can do whats called event sinking, how are you with VBA?

Ok, i'll tell you what to do and send a sample.

You need the following in your userform

Private colCustomTBs As Collection

Private Sub UserForm_Initialize()

Dim ctl As Control
Dim clsCustomTB As clsCustomTextBox

Set colCustomTBs = New Collection

For Each ctl In Me.Controls
    If TypeName(ctl) = "TextBox" Then
        Set clsCustomTB = New clsCustomTextBox
        Set clsCustomTB.CUSTOMTB = ctl
        colCustomTBs.Add clsCustomTB
    End If
Next ctl

End Sub

Then you need a class, called clsCustomTextBox, which has the code

Private WithEvents customTextBox As MSForms.TextBox

Public Property Set CUSTOMTB(objIn As MSForms.TextBox)
    Set customTextBox = objIn
End Property

Private Sub customTextBox_Change()
    If Mid(customTextBox.Name, 1, 1) = "I" Then
    
        '   Your code
    
    End If
End Sub

What this does is pass every textbox on the form initialisation and diverts it to be our customtextbox, which is inherited from MsForms.Textbox, we just mess about with the events.

HTH

1 Yes it does, you will need to put after the if Typename line,

if ctl.name<>"control1" AND ctl.name<>"control2" then

this will then omit the sinking for control1 and control2. Typename is the type name not the name.

2 Have you named your class clsCustomTextbox?

You could put this event code in the class module

Private Sub customTextBox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    Dim newString As String

    With customTextBox
        newString = Left(.Text, .SelStart) & Chr(KeyAscii) & Mid(.Text, .SelStart + .SelLength + 1)
    End With

    If newString Like "I*" Or newString Like "i*" Then
        MsgBox "Can't start with i"
        KeyAscii = 0
    End If
End Sub