Move Information Down a column

[Rabastan]

I Have a table in Excel that current look like this

Name 1	Item 1, Item 2, Item 3
Name 2	Item 1, Item 2

With 650+ Rows. What I need it for it to look like this

NAme 1	Item 1
Name 1	Item 2
Name 1	Item 3
Name 2	Item 1
Name 2	Item 2

There are about 20 Items that could be assigned to a name, They are fixed.

Is there a way to create a macro or series of macros the car make this change, as doing it by hand is going to take way too long.

Thanks in advance
Rab

[millz]

I assume your data starts at A1 and you have a header row, if not create a header row.

Try running this:

Sub SplitRows()
    Dim a, b, i As Long, j As Long
    With Range("A1").CurrentRegion
        a = .Value
        .Offset(1).Value = ""
        For i = 2 To UBound(a, 1)
            If InStr(a(i, 2), ",") > 0 Then
                b = Split(a(i, 2), ",")
                For j = 0 To UBound(b)
                    Range("A" & rows.Count).End(xlUp).Offset(1).Resize(, 2).Value = Array(a(i, 1), Trim(b(j)))
                Next
            Else
                Range("A" & rows.Count).End(xlUp).Offset(1).Resize(, 2).Value = Array(a(i, 1), a(i, 2))
            End If
        Next
    End With
End Sub

[Rabastan]

That Worked Awesome, Ty SO Much!! This will save me so much time.

Rab