Userform to rename caption of Multipage as per Checkbox

**calvinle** · 07-07-2014, 10:36 AM

Hi,

I have around 6 to 12 Checkbox, depends on the client, but I only create 4 multipage because they cannot add more than 4 different pages.

So I would like to, if the checkbox is clicked, the multipage caption will be renamed to the first clicked checkbox. If they uncheck it, it will undo the action.
If they check 2 checkboxes, it will rename the multipage accordingly to the first checkbox, and second checkbox which ever the one that got clicked first.

Example:
CheckBox1
CheckBox2
CheckBox3
CheckBox4
CheckBox5
CheckBox6

Page 1
Page 2
Page 3
Page 4

If CheckBox1 is checked, and CheckBox2 is checked, then
Page 1 Caption will be CheckBox1, Page2 caption will be CheckBox2.

If they decided to CheckBox1, CheckBox3, then CheckBox2, then
Page 1 caption will be CheckBox1, Page 2 caption will be CheckBox3, Page3 caption wil be CheckBox2 (as first one that got checked will be rename first)

If they decide to check over than the allowed Pages, it will prompt, you cannot add more than 4 checkbox.

I have attach the userform with the checkbox and pages.

Hope someone can help on this.

Thank you.1014468 UserformTest.xlsm

**mikerickson** · 07-07-2014, 10:49 AM

I could add as many pages as I like with this code

Me.MultiPage1.Pages.Add

(they were run time pages that had to be added every time the UF is invoked, like in the Initialize event

A Multi-page doesn't have a .Caption, but a .Page does.

Me.MultiPage1.Pages(0).Caption = "Hello"

I think this loop will do what you want

Dim I As Long

For I = 0 to 3
    Me.Multipage1.Pages(I).Visible = Me.Controls("Checkbox" & (I + 1)).Value
Next I

**Andy Pope** · 07-07-2014, 10:57 AM

Private mPageNames As Collection

Private Sub mUpdatePageNames()
    Dim Index As Long
    
    For Index = 1 To mPageNames.Count
        If Index > Me.MultiPage1.Pages.Count Then
            ' ignore
        Else
            Me.MultiPage1.Pages(Index - 1).Caption = mPageNames(Index)
        End If
    Next
    For Index = mPageNames.Count + 1 To Me.MultiPage1.Pages.Count
        Me.MultiPage1.Pages(Index - 1).Caption = ""
    Next
End Sub

Private Sub CheckBox1_Click()
    
    If CheckBox1.Value Then
        mPageNames.Add CheckBox1.Caption, "CHK1"
    Else
        mPageNames.Remove "CHK1"
    End If
    mUpdatePageNames
    
End Sub

Private Sub CheckBox2_Click()

    If CheckBox2.Value Then
        mPageNames.Add CheckBox2.Caption, "CHK2"
    Else
        mPageNames.Remove "CHK2"
    End If
    mUpdatePageNames

End Sub


Private Sub CheckBox3_Click()

    If CheckBox3.Value Then
        mPageNames.Add CheckBox3.Caption, "CHK3"
    Else
        mPageNames.Remove "CHK3"
    End If
    mUpdatePageNames

End Sub


Private Sub CheckBox4_Click()

    If CheckBox4.Value Then
        mPageNames.Add CheckBox4.Caption, "CHK4"
    Else
        mPageNames.Remove "CHK4"
    End If
    mUpdatePageNames

End Sub


Private Sub CheckBox5_Click()

    If CheckBox5.Value Then
        mPageNames.Add CheckBox5.Caption, "CHK5"
    Else
        mPageNames.Remove "CHK5"
    End If
    mUpdatePageNames

End Sub


Private Sub CheckBox6_Click()

    If CheckBox6.Value Then
        mPageNames.Add CheckBox6.Caption, "CHK6"
    Else
        mPageNames.Remove "CHK6"
    End If
    mUpdatePageNames

End Sub

Private Sub UserForm_Initialize()
    Set mPageNames = New Collection
    mUpdatePageNames
End Sub

Private Sub UserForm_Terminate()

    Set mPageNames = Nothing
    
End Sub