Wrong result adding values of text boxes in a userform.

Hello

I am not able to understand this.

I have 4 text boxes in a user form where user type numbers. At the end i have another text box(yellow one) that adds these numbers using this code.

Dim x As Integer, Tot As Double
    Me.TextBox5.Text = ""
    For x = 1 To 4
    Tot = Tot + Val(Me("prcase" & x).Text)
    Next x
    Me.TextBox5.Text = Tot

In another text box(grey one) user types another number.

Then using this code

Private Sub TextBox6_Change()
TextBox7.Text = Val(TextBox5.Text) + Val(TextBox6.Text)
End Sub

i try to add the values of the two previous text boxes.

I get wrong result when i use decimals numbers and i can not understand what is wrong.

Thanks in advance for any assistance here.

What are you using as a decimal separator when you enter values?

decimals need to go as doubles, so dblValue1=cdbl(textbox1.text) and dblValue2=cdbl(textbox2.text)

then tot will be the sum of the two doubles, tot will need to be a double to.

I'd put in an ISNUMERIC() check on both boxes before running the sub.

We use COmma in Greece MR Norie.

The first video is using nathansav's suggestion like this.

Private Sub TextBox6_Change()
TextBox7.Text = CDbl(TextBox5.Text) + CDbl(TextBox6.Text)
End Sub

http://screencast.com/t/05SPHBl9w

and the other one as i mentioned in my first post

http://screencast.com/t/OY9WKHrlJ

The problem is the comma, if you use a period (.) for the separator the total should calculate correctly.

Try this code to see what the results are when you use Val/Dbl and comma/period, I've also added in an empty string to show what will happen if a textbox is empty.

Msgbox Val("1,3")
MsgBox Val("1.3")
MsgBox CDbl("1,3")
MsgBox CDbl("1.3")
MsgBox Val("")
MsgBox CDbl("")

I get these results Mr Norie.

First time i run your code i get 1

click OK>>1,3
click OK>>1,3
click OK>>13
click OK>>0
and clicking OK again, i get an error with highlighting the last line of your code.

Does this work?

Private Sub prcase1_Change()
    SumTextBoxes
End Sub

Private Sub prcase2_Change()
    SumTextBoxes
End Sub

Private Sub prcase3_Change()
    SumTextBoxes
End Sub

Private Sub prcase4_Change()
    SumTextBoxes
End Sub

Private Sub TextBox6_Change()
    TextBox7.Text = Val(Replace(TextBox5.Text, ",", ".")) + Val(Replace(TextBox6.Text, ",", "."))
End Sub

Sub SumTextBoxes()
Dim x As Long, Tot As Double

    Me.TextBox5.Text = ""
    
    For x = 1 To 4
        Tot = Tot + Val(Replace(Me("prcase" & x).Text, ",", "."))
    Next x
    
    Me.TextBox5.Text = Tot
    
End Sub

Of course it's works!!!!

Thank you very much!