Subscript out of range error, not sure why

Im trying to make a code that will let me select another excel document, i want to copy a cell, and paste it into my original excel file. This keeps giving various errors, and i cant seem to find the best way to do this. Would appreciate any help. (the code isnt done either, i just dont want to make the rest before i know that this part works.)

This is my code so far

Sub test()
Dim wb As Workbook
Dim wb2 As Workbook
Dim vFile As Variant
Application.EnableEvents = False
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.Calculation = xlManual

Set wb = ActiveWorkbook

vFile = Application.GetOpenFilename("Excel-files,*.xlsx", _
1, "Select One File To Open", , False)

If TypeName(vFile) = "Boolean" Then Exit Sub
Workbooks.Open vFile
'Set targetworkbook
Set wb2 = ActiveWorkbook
wb2.Worksheets("Sheet1").Range("C12").Copy
Set wb = ActiveWorkbook

wb.Worksheets("Data").Range("B1").Select ' This step keeps yielding the error
Selection.PasteSpecial Paste:=xlPasteValues


End Sub

It looks to me as though you are trying to copy the C12 on Sheet1 in the vFile workbook to B1 on the Data sheet in vFile. Given that you are using getopenfilename, presumably the file that is open sometimes doesn't have a sheet named Data?

Maybe try:

Sub test()
 Dim wb As Workbook
 Dim wb2 As Workbook
 Dim vFile As Variant
 Application.EnableEvents = False
 Application.ScreenUpdating = False
 Application.DisplayAlerts = False
 Application.Calculation = xlManual
 Set wb = ActiveWorkbook
 vFile = Application.GetOpenFilename("Excel-files,*.xlsx", _
 1, "Select One File To Open", , False)
 If TypeName(vFile) = "Boolean" Then Exit Sub
 Set wb2 = Workbooks.Open(vFile)
 wb.Sheets("Data").Range("B1").Value = wb2.Sheets(1).Range("C12").Value
 Application.EnableEvents = True
 Application.ScreenUpdating = True
 Application.DisplayAlerts = True
 End Sub

is the
Set wb = activeworkbook
what makes it not work? i tried replacing that step with
wb.Sheets("Data").Activate
but now that step is the one not working

i do have a sheet called data where i want to paste my data. i tried your code and it gives me "automated error on this step:
wb.Sheets("Data").Range("B1").Value = wb2.Sheets(1).Range("C12").Value

In your original code the second set wb = activeworkbook will overwrite the first so both will be copying to the same workbook.

I just double checked my code and tested it, providing there is a sheet called Data in the active workbook when you run the code then it seems to run ok.

It might be worth trying:

Sub test()
 Dim wb As Workbook
 Dim wb2 As Workbook
 Dim vFile As Variant
 Application.EnableEvents = False
 Application.ScreenUpdating = False
 Application.DisplayAlerts = False
 Application.Calculation = xlManual
 Set wb = ThisWorkbook
 vFile = Application.GetOpenFilename("Excel-files,*.xlsx", _
 1, "Select One File To Open", , False)
 If TypeName(vFile) = "Boolean" Then Exit Sub
 Set wb2 = Workbooks.Open(vFile)
 wb.Sheets("Data").Range("B1").Value = wb2.Sheets(1).Range("C12").Value
 Application.EnableEvents = True
 Application.ScreenUpdating = True
 Application.DisplayAlerts = True
 End Sub

which will copy the data into the workbook the code is saved in, rather than the active one.

that worked! thank you so much. Im sure ill be back with a new thread as soon as the next problem arises :P