when use vba to open file, How to notify the user when the excel are opened by other

This macro will notify you whether or not the workbook is open.

Sub Test()
    Dim WB As Workbook
    On Error Resume Next
    Set WB = Workbooks("abc.xlsm")
    If WB Is Nothing Then
        MsgBox "The workbook abc.xlsm is not open."
        Set WB = Nothing
        On Error GoTo 0
    Else
        MsgBox "The workbook abc.xlsm is open."
        Set WB = Nothing
        On Error GoTo 0
    End If
End Sub

Hi,

Check the below code and hope it will help you :

Sub TestFileOpened()

    ' Test to see if the file is open.
    If IsFileOpen("D:\Book2.xlsx") Then
        MsgBox "File already in use!"
    Else
        ' Display a message stating the file is not in use.
        MsgBox "File not in use!"
    End If

End Sub

Function IsFileOpen(filename As String)
    Dim filenum As Integer, errnum As Integer

    On Error Resume Next
    filenum = FreeFile()
    Open filename For Input Lock Read As #filenum
    Close filenum          ' Close the file.
    errnum = Err           ' Save the error number that occurred.
    On Error GoTo 0        ' Turn error checking back on.

    Select Case errnum

        Case 0
         IsFileOpen = False

        Case 70
            IsFileOpen = True

        Case Else
            Error errnum
    End Select

End Function

Regards,
Paresh J