Only accept integers in a text box with linked spin button

Hi All,

I have a linked text box and spin button on a userform so the user can enter text or use the buttons and I'm having trouble barring non-integer inputs! Here's what I have so far:

Text box = NumberBox
Spin button= NumberSpin

Private Sub NumberBox_Change()

If IsNumeric(Me.NumberBox.Text) Then
Me.NumberSpin.Value = Me.NumberBox.Text
ElseIf Me.NumberBox.Text = "" Then
Me.NumberSpin.Value = False
Else
    MsgBox "Qty must be a whole number"
    Me.NumberBox.Text = prevvalue
    

End If
End Sub


Private Sub NumberSpin_Change()

If IsNumeric(Me.NumberBox.Text) Or Me.NumberBox.Text = "" Then
    Me.NumberBox.Text = Me.NumberSpin.Value
    Else
    prevvalue = Me.NumberBox.Text
End If

End Sub

Any help would be greatly appreciated. Thanks!

Assuming you have your global variable called prevvalue already setup in a module, you can use this code to do what you're looking for:

Private Sub NumberSpin_SpinDown()
    Me.NumberBox.Text = Me.NumberBox.Value - 1
    prevvalue = Me.NumberBox.Value
End Sub

Private Sub NumberSpin_SpinUp()
    Me.NumberBox.Text = Me.NumberBox.Value + 1
    prevvalue = Me.NumberBox.Value
End Sub

Private Sub NumberBox_Change()
    If Not IsNumeric(Me.NumberBox.Value) Then
        MsgBox "Numeric values only.", vbcritical + vbokonly, "Invalid input"
        Me.NumberBox.Value = prevvalue
        GoTo skipmark
    End If
    If Not (Me.NumberBox.Value - (Me.NumberBox.Value \ 1)) = 0 Then
        MsgBox "Invalid value, use integers only.", vbcritical + vbokonly, "Invalid input"
        Me.NumberBox.Value = prevvalue
    Else
        prevvalue = Me.NumberBox.Value
    End If
skipmark:
End Sub

Private Sub UserForm_Initialize()
    prevvalue = 0
    Me.NumberBox.Text = "0"
End Sub

Hi nathansav,

The code above was from something else I got help with about a month ago, thread here:

http://www.excelforum.com/excel-prog...ric-input.html

I'm now working on something different that can only accept integers (whereas the previous application could handle any numerical input).

I've tried Int() and CInt() to overwrite the text box after all the other conditions have been fulfilled but I can't figure it out.

Many Thanks

^That's great thanks. I put an extra argument in to reject negative numbers (sorry, forgot to mention that) and it works a treat. Many Thanks