using vba macro to change all charts at same time

Hi Everyone,

I have about 60 charts in my active worksheet that I would like to change the size and font of.
I already wrote the code to run it on one, but I would like a piece of code that runs it automatically on al the charts in the active worksheet. How should I adjust the code?

Sub adjustcharts()
With ActiveChart.Axes(xlValue).TickLabels.font
.Size = 8
.color = vbBlack
.Name = "Calibri (Body)"
.FontStyle = "Regular"
End With
With ActiveChart.Axes(xlCategory).TickLabels.font
.Size = 8
.color = vbBlack
.Name = "Calibri (Body)"
.FontStyle = "Regular"
End With
With ActiveChart.Legend.font
.Size = 8
.color = vbBlack
.Name = "Calibri (Body)"
.FontStyle = "Regular"
End With
With ActiveChart.Parent
.Height = 216 ' resize 2.5 pt at 72 ppi.
.Width = 328.32 ' resize 4.0 pt at 72 ppi.

End With
End Sub

Thanks a million!!

Crosspost: http://www.mrexcel.com/forum/excel-q...eet-macro.html

Crosspost

http://www.mrexcel.com/forum/excel-q...eet-macro.html

See this link for crossposting


http://www.excelguru.ca/content.php?184

For the members who follow this threat.

And the code below is the given answer on mrexcel.

Sub adjustcharts()
    Dim oCht As ChartObject
    
    For Each oCht In ActiveSheet.ChartObjects
        With oCht.Chart
            With .Axes(xlValue).TickLabels.Font
                .Size = 8
                .Color = vbBlack
                .Name = "Calibri (Body)"
                .FontStyle = "Regular"
            End With
            With .Axes(xlCategory).TickLabels.Font
                .Size = 8
                .Color = vbBlack
                .Name = "Calibri (Body)"
                .FontStyle = "Regular"
            End With
            With .Legend.Font
                .Size = 8
                .Color = vbBlack
                .Name = "Calibri (Body)"
                .FontStyle = "Regular"
            End With
        End With
        oCht.Height = 216 ' resize 2.5 pt at 72 ppi.
        oCht.Width = 328.32 ' resize 4.0 pt at 72 ppi.
    Next oCht
End Sub