How to split worksheet into multiple worksheets based on column content

I'm trying to break up a worksheet into several worksheets based on the data in the "branch" column.
I've tried to use other codes posted here, but, I can't seem to nail down the debug process and accurately identify the cells/columns that I need.
I have a header row of 7 columns:
member_id nps comments additional_comments Call Me! Number Branch

the data in the "branch" column is the one I need to be the defining one for creating the new worksheets. How do I modify/create the module code?

Difficult to provide an answer on your code, if you have not provided it. Suggest you post your code and a sanitized copy of your spreadsheet. It is easier to provide a solution when we can actually see the problem.

Attach a sample workbook. Make sure there is just enough data to demonstrate your need. Include a BEFORE sheet and an AFTER sheet in the workbook if needed to show the process you're trying to complete or automate. Make sure your desired results are shown, mock them up manually if necessary.

Remember to desensitize the data.

Click on GO ADVANCED and use the paperclip icon to open the upload window.

View Pic

Option Explicit

Sub ParseSiteData()
'JBeaucaire  (11/11/2009)
'Based on column A, data is filtered to individual sheets
'Creates sheets and sorts alphabetically in workbook
Dim LR As Long, i As Long, MyArr
Dim MyCount As Long, ws As Worksheet
Application.ScreenUpdating = False

Set ws = Sheets("Data")      'edit to sheet with master data
ws.Activate

Rows(1).Insert xlShiftDown
Range("A1") = "Key"
Columns("A:A").AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Range("CC1"), Unique:=True
Columns("CC:CC").Sort Key1:=Range("CC2"), Order1:=xlAscending, Header:=xlYes, _
    OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
MyArr = Application.WorksheetFunction.Transpose(Range("CC2:CC" & Rows.Count).SpecialCells(xlCellTypeConstants))

Range("CC:CC").Clear
Range("A1").AutoFilter

For i = 1 To UBound(MyArr)
    ws.Range("A1").AutoFilter Field:=1, Criteria1:=MyArr(i)
    LR = ws.Range("A" & Rows.Count).End(xlUp).Row
    If LR > 1 Then
        If Not Evaluate("=ISREF('" & MyArr(i) & "'!A1)") Then
            Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = MyArr(i)
        Else
            Sheets(MyArr(i)).Move After:=Sheets(Sheets.Count)
            Sheets(MyArr(i)).Cells.Clear
        End If
        ws.Range("A2:A" & LR).SpecialCells(xlCellTypeVisible).EntireRow.Copy _
            Sheets(MyArr(i)).Range("A1")
        ws.Range("A1").AutoFilter Field:=1
        MyCount = MyCount + Sheets(MyArr(i)).Range("A" & Rows.Count).End(xlUp).Row - 1
        Sheets(MyArr(i)).Columns.AutoFit
    End If
Next i

ws.Activate
ws.AutoFilterMode = False
LR = ws.Range("A" & Rows.Count).End(xlUp).Row - 1
Rows(1).Delete xlShiftUp
MsgBox "Rows with data: " & LR & vbLf & "Rows copied to other sheets: " & MyCount & vbLf & "Hope they match!!"
Application.ScreenUpdating = True
End Sub

Hi

Assuming the Branch column contains lots of duplicates then the first thing you need to do is extract a unique list of branches.
If you have Excel 2010 then you can use the 'RemoveDuplicates' option after you have copied the range. Alternatively you could use an Advanced Data Filter to create a unique list

e.g.

Sheet1.Range("G2:G1000").Copy Destination:=Sheet1.Range("L1"), Unique:=True

Then loop down the list starting in L1 with the following macro. Change the reference to Sheet1 as necessary

Sub AddSheet()
    Dim c As Long
    c = 1
    Do While Sheet1.Range("L" & c) <> ""
        Worksheets.Add.Name = Sheet1.Range("L" & c)
        c = c + 1
    Loop
End Sub

However before splitting data into several sheets I'd urge you to consider why you need to do this. I've lost count of the number of times people have started out with data that's spread across many sheets, (often sheets for different years, months or even days) and then found that summarising/analysing the whole lot of data is rendered very difficult.

If you have a database and you periodically need to report specific branch information then the smart way is to use a separate sheet which is populated with Branch details with a Data Advanced Filter at run time.

What is the overall aim here?

Let's try this one.

Sub PagesByDescription()
Dim rRange As Range, rCell As Range
Dim wSheet As Worksheet
Dim wSheetStart As Worksheet
Dim strText As String

    Set wSheetStart = ActiveSheet
    wSheetStart.AutoFilterMode = False
    'Set a range variable to the correct item column
    Set rRange = Range("G1", Range("G65536").End(xlUp))
    
        'Delete any sheet called "UniqueList"
        'Turn off run time errors & delete alert
        On Error Resume Next
        Application.DisplayAlerts = False
        Worksheets("UniqueList").Delete
        
        'Add a sheet called "UniqueList"
        Worksheets.Add().Name = "UniqueList"
        
           'Filter the Set range so only a unique list is created
            With Worksheets("UniqueList")
                rRange.AdvancedFilter xlFilterCopy, , _
                 Worksheets("UniqueList").Range("A1"), True
                 
                 'Set a range variable to the unique list, less the heading.
                 Set rRange = .Range("A2", .Range("A65536").End(xlUp))
            End With
            
            On Error Resume Next
            With wSheetStart
                For Each rCell In rRange
                  strText = rCell
                 .Range("A1").AutoFilter 7, strText
                    Worksheets(strText).Delete
                    'Add a sheet named as content of rCell
                    Worksheets.Add().Name = strText
                    'Copy the visible filtered range _
                    (default of Copy Method) and leave hidden rows
                    .UsedRange.Copy Destination:=ActiveSheet.Range("A1")
                    ActiveSheet.Cells.Columns.AutoFit
                Next rCell
            End With
            
        With wSheetStart
            .AutoFilterMode = False
            .Activate
        End With
        
        On Error GoTo 0
        Application.DisplayAlerts = True
End Sub

You are welcome and thanks for the feedback.

Pls, next time, be carefull with rules of the forum, because my intention IS NOT to be the bad quy here!!