how do I get the first array value of the loop?

[bbmak]

I use this vba to split my excel sheets into multiple files, however, the first sheet into a file usually the original file, and it will be delete.
Right now I am hard coding it with Kill mypath & "\sheet1.xlsx"
Are there anyway to make it dynamic or a string?

can I do something like sht.Name(0) ??? Get the first value of the array?

Sub Splitbook()

mypath = ActiveWorkbook.Path
For Each sht In ActiveWorkbook.Sheets
sht.Copy
ActiveSheet.Cells.Copy
ActiveSheet.Cells.PasteSpecial Paste:=xlPasteValues
ActiveSheet.Cells.PasteSpecial Paste:=xlPasteFormats
ActiveWorkbook.SaveAs _
Filename:=mypath & "\" & sht.Name & ".xlsx"
ActiveWorkbook.Close savechanges:=False
Next sht
Kill mypath & "\sheet1.xlsx"
End Sub

[shg]

You should get in the habit of declaring your variables.

Sub Splitbook()
    Dim sPath       As String
    Dim i           As Long

    sPath = ActiveWorkbook.Path

    For i = 2 To ActiveWorkbook.Worksheets.Count
        Worksheets(i).Copy
        With ActiveSheet
            .UsedRange.Value = .UsedRange.Value
            .Parent.SaveAs Filename:=sPath & "\" & .Name & ".xlsx"
            .Parent.Close SaveChanges:=False
        End With
    Next i
End Sub

[AlphaFrog]

This avoids copying the 1st sheet.

Sub Splitbook()
    Dim i As Long, mypath As String
    mypath = ThisWorkbook.Path
    Application.ScreenUpdating = False
    For i = 2 To ThisWorkbook.Sheets.Count
        ThisWorkbook.Sheets(i).Copy
        ActiveSheet.UsedRange.Value = ActiveSheet.UsedRange.Value
        ActiveWorkbook.SaveAs _
                Filename:=mypath & "\" & ActiveSheet.Name & ".xlsx"
        ActiveWorkbook.Close SaveChanges:=False
    Next i
    Application.ScreenUpdating = True
End Sub

[bbmak]

Thank Guys, it works.

@shg
yes, i am a bad vba programmer.... I really need to get that into practice.

[shg]

You're welcome.