Cycle through all .xlsb files in a folder in size order (largest first)

[cochise]

Is it possible to create excel vba code to cycle through and open all .xlsb files in a particular folder starting with the largest filesize first?
All methods I have seen so far use alpha order.
Many thanks for any help you can give.

[Norie]

The only way I can think of doing it would be to first read in the names and sizes of all the xlsb files in the folder to a list, sort the list by size and then loop through the list opening the files.

Something like this perhaps.

Dim strPath As String
Dim strFileName As String
Dim I As Long

    strPath = "C:\Test\"

    strFileName = Dir(strPath & "*.xlsb")

    Range("A1:B1").Value = Array("FileName", "Size (bytes)")

    Do While Len(strFileName) <> 0

        With Range("A" & Rows.Count).End(xlUp).Offset(1)
            .Value = strPath & strFileName
            .Offset(, 1).Value = FileLen(.Value)
        End With

        strFileName = Dir()
    Loop

    With Worksheets("Sheet1")
        .Sort.SortFields.Clear
        .Sort.SortFields.Add Key:=.Range("A1").CurrentRegion.Columns(2) _
                                  , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With .Sort
            .SetRange Worksheets("Sheet1").Range("A1").CurrentRegion
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With
    
    For I = 2 To Worksheets("Sheet1").Range("A" & Rows.Count).End(xlUp).Row
        Set wbOpen = Workbooks.Open(Worksheets("Sheet1").Range("A" & I))
        
        ' do stuff with workbook
        
        wbOpen.Close SaveChanges:=True
        
    Next I

[cochise]

Thank you so much for your prompt response.
The code worked perfectly and I would never have thought to do it that way.