This should do it:

Option Explicit

Sub MergeUP()
'Jerry Beaucaire   5/20/14
'Merges text data upward based on text match in the given column.
Dim vCOL As Long, RW As Long, LR As Long, Col As Long, LC As Long, DelRNG As Range

vCOL = 3                                            'this is the column we will match by
LR = Range("A" & Rows.Count).End(xlUp).Row          'last row of data
LC = Cells(1, Columns.Count).End(xlToLeft).Column   'last column

Application.ScreenUpdating = False                  'speed up macro
                                                    'sort the data by names and ID in column A
Range("A1").CurrentRegion.Sort Cells(2, vCOL), xlAscending, Cells(2, "A"), , xlAscending, Header:=xlYes

For RW = LR To 3 Step -1                            'merge from the bottom up
    If Cells(RW, vCOL).Value = Cells(RW - 1, vCOL).Value Then   'if the vcol value matches the row above
        For Col = 1 To LC                           'then cycle through each column to test and merge up
            If Col <> vCOL Then                     'skip the column being used for the value match
                                                    'if current row is not blank, copy to matched row above
                If Len(Cells(RW, Col).Value) > 0 Then Cells(RW - 1, Col).Value = Cells(RW, Col).Value
            End If
        Next Col
                                                    'memorize the rows that will be deleted at the end
        If DelRNG Is Nothing Then Set DelRNG = Cells(RW, "A") Else Set DelRNG = Union(DelRNG, Cells(RW, "A"))
    End If
    Application.StatusBar = "Progress: " & RW & " rows remaining..."        'update the lower left status bar to indicate progress
Next RW

If Not DelRNG Is Nothing Then DelRNG.EntireRow.Delete xlShiftUp             'delete the unneeded rows
Application.ScreenUpdating = True                   'update the screen
Application.StatusBar = False                       'clear the status bar
End Sub

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED. Thanks.