Case Statement with Multiple Conditions

Hello,

I'm trying to write a case statement for 4 different cases based on 2 worksheets and if they are visible or not. Ex.

Case Neither x or y visible
Do 1

Case Both x and y visible
Do 2

Case Sheet x visible
Do 3

Case Sheet y visible
Do 4

There will always be other sheets visible so I need the cases to be specific. I've tried multiple combinations and can't get them to work as describe above. Biggest problem is when both or neither are visible.

Thanks for the help.

Sub test()
    Dim x As Worksheet, y As Worksheet
    Set x = Sheets("sheet1")
    Set y = Sheets("sheet2")
    Select Case True
        Case x.Visible <> -1 And y.Visible <> -1
            ' do 1
        Case x.Visible = -1 And y.Visible = -1
            ' do 2
        Case x.Visible = -1
            ' do 3
        Case y.Visible = -1
            ' do 4
    End Select
End Sub

Thanks to all that replied, I tried jindon and TMS's offering and they both worked as asked but it appears that I didn't ask the question correctly. I didn't realize that not visible (hidden) and non existent weren't the same thing. If the sheets are simply hidden all works well but if the sheets don't exists I get debugger. I am actually copying sheets form another workbook so sometimes one sheet exists and not the other or visa-versa, sometimes both exist and sometimes neither exists. Can you please help me restructure the code base on the existence of the sheet rather than visibility.

In that case

Sub test()
    Dim x As Worksheet, y As Worksheet
    On Error Resume Next
    Set x = Sheets("sheet1")
    Set y = Sheets("sheet2")
    On Error GoTo 0
    Select Case True
        Case x Is Nothing And y Is Nothing
            ' do 1
        Case Not x Is Nothing And Not y Is Nothing
            ' do 2
        Case Not x Is Nothing
            ' do 3
        Case Not y Is Nothing
            ' do 4
    End Select
End Sub

That did the trick jindon, many thanks!