Excel macro that can open up a website and input a user name and password.

Hello,
I am having trouble finding code that will work with this website.
I found the following code but it keeps opening the website and giving me the following error message: "Object variable or With block variable not set"
can any one help me? I would also perfer to use chrome instead of IE if possible.
Thanks,

Sub LoginToURL()
    Dim ie As Object, iebody As String, strURL As String, strUsername As String, strPassword As String
     
    Set ie = CreateObject("InternetExplorer.Application")
     
    strURL = "http://www.costar.com/"
    strUsername = "Username here"
    strPassword = "password here"
     
    ie.Navigate strURL
     'Wait until page is loaded.
    While ie.ReadyState < 4 ' READYSTATE_COMPLETE = 4
        DoEvents
    Wend
     
    ie.Visible = True
     
    ie.Document.All("username").Value = strUsername
    ie.Document.All("password").Value = strPassword
    ie.Document.All("sign-in-button").Click
     
     'Wait until page is loaded.
    While ie.ReadyState < 4 ' READYSTATE_COMPLETE = 4
        DoEvents
    Wend
     
    Application.Wait (Now + TimeValue("0:00:05"))
     
    iebody = ie.Document.body.innerhtml
     
    If InStr(iebody, "The information you entered is invalid.") <> 0 Then
        MsgBox "Login failed!", vbCritical + vbOKOnly
    Else
        MsgBox "Login successful!", vbInformation + vbOKOnly
    End If
     
    ie.Quit
    Set ie = Nothing
     
End Sub

You're probably getting the error because the login form is in a different frame and not actually on the page. You would need to login through the source the login form is on which is not the main page.

Uee this as the login url and it will work

HTML Code: 

Here is your updated code.

Sub LoginToURL()
    Dim ie As Object, iebody As String, strURL As String, strUsername As String, strPassword As String
     
    Set ie = CreateObject("InternetExplorer.Application")
     
    strURL = "https://www.costar.com/PortalPublic/SSL/Login.aspx?c=30&LangType=1033"
    strUsername = "Username here"
    strPassword = "password here"
     
    ie.Navigate strURL
     'Wait until page is loaded.
    While ie.ReadyState < 4 ' READYSTATE_COMPLETE = 4
        DoEvents
    Wend
     
    ie.Visible = True
     
    ie.Document.All("username").Value = strUsername
    ie.Document.All("password").Value = strPassword
    ie.Document.All("oLoginButton").Click
     
     'Wait until page is loaded.
    While ie.ReadyState < 4 ' READYSTATE_COMPLETE = 4
        DoEvents
    Wend
     
    Application.Wait (Now + TimeValue("0:00:05"))
     
    iebody = ie.Document.body.innerhtml
     
    If InStr(iebody, "The information you entered is invalid.") <> 0 Then
        MsgBox "Login failed!", vbCritical + vbOKOnly
    Else
        MsgBox "Login successful!", vbInformation + vbOKOnly
    End If
     
    ie.Quit
    Set ie = Nothing
     
End Sub

If you need a full login pge try this one:

HTML Code: 

Sorry I forgot I had to change that as well. Glad I could help.