Monitor multiple cells for an input event

Below is code supplied by JBeaucaire and it works exactly as I requested. However, I need this to happen for multiple cells.

The cells that I need to monitor are B10, B12, B14.... through B96 and F, J, N, R columns for the same rows. The input values will be stored in cells AM10, AM12, AM14 .... through 96 for the B column results. Then for F, J, N, R will be AQ, AU, AY and BC respectively.

Additionally, when B10 has an input, and the user input box displays for the number of hours, there is a cancel button available, but it does not work. How can I exit the loop and clear contents of B10 if the "Cancel" button is clicked in the dialogue box.

I know I'm asking alot. thanks in advance.

Option Explicit

Private Sub Worksheet_Activate()
    If Range("B10") = "" And Range("AM10") <> "" Then Range("AM10").ClearContents
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
Dim MyVal As Single

    If Not Intersect(Target, Range("B10")) Is Nothing Then
        If Range("B10") <> "" Then
            Do
                MyVal = Application.InputBox("How many hours for this task: " & Range("B10").Value, "Hours", Type:=1)
                If MyVal > 0 Then
                    Range("AM10").Value = MyVal
                    Exit Do
                End If
            Loop
        Else
            Range("AM10").ClearContents
        End If
    End If

End Sub

I would remove the ws_Activate macro completely, that's impractical for the increased scope. Then this should work since your column associations are consistently 37 columns apart.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim MyVal As Single, MyCol As Long

Select Case Target.Cells(1).Column
    Case 2, 6, 10, 14, 18                       'columns B, F, J, N and R
        MyCol = Target.Cells(1).Column + 37     'column AM, AQ, AU, AY and BC
        If Target.Cells(1).Value <> "" Then
            Do
                MyVal = Application.InputBox("How many hours for this task: " & Target.Cells(1).Value, "Hours", Type:=1)
                If MyVal > 0 Then
                    Cells(Target.Cells(1).Row, MyCol).Value = MyVal
                    Exit Do
                End If
            Loop
        Else
            Cells(Target.Cells(1).Row, MyCol).ClearContents
        End If
    
    Case Else
        'do nothing
End Select
    
End Sub

What do you mean? The hours are a requirement aren't they?

Then perhaps:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim MyVal As Single, MyCol As Long

Select Case Target.Cells(1).Column
    Case 2, 6, 10, 14, 18                       'columns B, F, J, N and R
        MyCol = Target.Cells(1).Column + 37     'column AM, AQ, AU, AY and BC
        If Target.Cells(1).Value <> "" Then
            MyVal = Application.InputBox("How many hours for this task: " & Target.Cells(1).Value, "Hours", Type:=1)
            If MyVal > 0 Then Cells(Target.Cells(1).Row, MyCol).Value = MyVal Else Application.Undo
        Else
            Cells(Target.Cells(1).Row, MyCol).ClearContents
        End If
    
    Case Else
        'do nothing
End Select

End Sub