VBA not cycling through and processing all files in folder

There is no loop in that code.

You could try this version of your original code:

Option Explicit
 
 
Sub FixDates()
     
     
    Dim SelectFolder As String
    Dim csvFiles As Variant
    Dim csvWb As Workbook
    Dim x As Integer
    
    Application.DisplayAlerts = False

     
     'browse for folder with csv files
    On Error GoTo FixCsvFiles_Error
    SelectFolder = GetFolder("c:\")
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationAutomatic
     'Check user did not cancel folder selection
    If SelectFolder = "" Then
        MsgBox "No Folder Selected - Cannot continue", vbCritical
        End
    End If
     
    SelectFolder = SelectFolder & "\"
    csvFiles = Dir(SelectFolder & "*.csv")
    Do While csvFiles <> ""
         
        Set csvWb = Workbooks.Open(Filename:=SelectFolder & csvFiles, local:=True)
        With csvWb.ActiveSheet
            With .Range("F2:F228")
                .FormulaR1C1 = "=TEXT(RC[-2],""YYYY-MM-DD"")"
                .Copy
            End With
            With .Range("D2:D228")
                .PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _
                                    SkipBlanks:=False, Transpose:=False
                .PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, _
                                    SkipBlanks:=False, Transpose:=False
            End With
            .Range("F2:F228").ClearContents
            .Range("A229:E300").ClearContents
        End With
        x = x + 1
        Application.DisplayAlerts = False
        csvWb.Close SaveChanges:=True
        Application.DisplayAlerts = True
        csvFiles = Dir
    Loop
    Application.ScreenUpdating = True
    MsgBox "A total of " & CStr(x) & " files processed", vbInformation
    On Error GoTo 0
    Application.DisplayAlerts = True
    Exit Sub
     
FixCsvFiles_Error:
     
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure FixCsvFiles of Module2"
End Sub
 
 
Function GetFolder(strPath As String) As String
    Dim fldr As FileDialog
    Dim sItem As String
     
     
    Set fldr = Application.FileDialog(msoFileDialogFolderPicker)
    With fldr
        .Title = "BROWSE TO FOLDER LOCATION WITH CSV FILES"
        .AllowMultiSelect = False
        .InitialFileName = strPath
        If .Show <> -1 Then GoTo NextCode
        sItem = .SelectedItems(1)
    End With
NextCode:
    GetFolder = sItem
    Set fldr = Nothing
End Function