Sorting sheets by calling sub procedures.

[Excelnoub]

Good day,
I am just looking to enhance this procedure when sorting. My setting is at the “Page Break Preview”. I feel like the view is much better, I guess to each their own.
I have sorting procedure stored in my module 3, I have around 6 sorting that will sort different sheets. In some of my codes, I call sometime 3 at a time as my information constantly updates.
I was looking at my sheet after the procedure was running and it was not doing as the code is written. I am just looking to see if this could be improved or and modified to not have the print selection “Snapped on” when I call these procedures.
Sort from Sheet1:

Sub Sort1()
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    With ActiveWorkbook.Worksheets("Pre-Solicitation").Sort
        .SetRange Range("A5:M20")
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Range("A5").Select
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub

The reason I am adding the Range selection at the end is that I havent found how to deselect the full screen. When I call the Sub Proceedure on 2 different Sorts it will generate the first sheet while doing the full proceedure but then if I go to my sheet2 I will see that it did not run the range selection.

Sheet 2 sub:

Sub Sort2()
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    With ActiveWorkbook.Worksheets("GETS").Sort
        .SetRange Range("A5:F20")
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Range("A5").Select
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub

Is there a method for the Sheet to do like a unselect all...

[Excelnoub]

I also have this in a userfrom:

Private Sub CommandButton1_Click()
Application.ScreenUpdating = False
Application.EnableEvents = False

'..........Other proceedures

     Call Sort1
     Call Sort2
     Call Sort5
     Unload Me

Application.ScreenUpdating = True
Application.EnableEvents = True
    
End Sub

[Excelnoub]

This is what I have to insert in my Userform everytime but was wondering if there would be an easier method

Sheets("Pre-Solicitation").Select
Range("A5").Select
Sheets("GETS").Select
Range("A5").Select
Sheets("Pre-Solicitation").Select

So that my Code would look like this at the end:

Private Sub CommandButton1_Click()
Application.ScreenUpdating = False
Application.EnableEvents = False

'..........Other proceedures

Call Sort1
Call Sort2
Call Sort5
Unload Me

Sheets("Pre-Solicitation").Select
Range("A5").Select
Sheets("GETS").Select
Range("A5").Select
Sheets("Pre-Solicitation").Select

Application.ScreenUpdating = True
Application.EnableEvents = True

End Sub

But I don't get it cause I am doing the same thing in my Sub Sort...

[Excelnoub]

I guess for a better understanding of what it is doing:

You will see that when you Click on Sort 1 it will do exacly what it is supposed to do but when you click and Sort 1 and 2 or Sort all it will Select all information on sheet from Sheet2 and 3.

I need to remove the selection.

Sort.xlsm

[Excelnoub]

Found a shorter code for my Subs but when I call them Only the first sub is generated:


Module1

Sub Sort1()
    With Sheets(1)
    Range("A5:M20").Sort Key1:=Range("A5")
    End With
End Sub

Sub Sort2()
    With Sheets(2)
    Range("A5:F20").Sort Key1:=Range("A5")
    End With
End Sub

Sub Sort3()
    With Sheets(3)
    Range("A5:E20").Sort Key1:=Range("A5")
    End With
End Sub

Sheet1:

Private Sub CommandButton1_Click()
    Call Sort1
End Sub

Private Sub CommandButton2_Click()
    Call Sort1
    Call Sort2
End Sub

Private Sub CommandButton3_Click()
    Call Sort1
    Call Sort2
    Call Sort3
End Sub

[Excelnoub]

GOT IT

Module:

Sub Sort1()
    With ActiveWorkbook.Worksheets("Pre-Solicitation").Select
    Range("A5:M20").Sort Key1:=Range("A5")
    Range("A5").Select
    End With
End Sub

Sub Sort2()
    With ActiveWorkbook.Worksheets("GETS").Select
    Range("A5:F20").Sort Key1:=Range("A5")
    Range("A5").Select
    End With
End Sub

Sub Sort3()
    With ActiveWorkbook.Worksheets("Evaluation").Select
    Range("A5:E20").Sort Key1:=Range("A5")
    Range("A5").Select
    End With
End Sub

[Norie]

Your Withs aren't really doing anything.

Try sprinkling some dot qualifiers, '.', over the code.

Sub Sort1()
    With ActiveWorkbook.Worksheets("Pre-Solicitation")
        .Range("A5:M20").Sort Key1:=.Range("A5")
    End With
End Sub

Sub Sort2()
    With ActiveWorkbook.Worksheets("GETS")
        .Range("A5:F20").Sort Key1:=.Range("A5")
    End With
End Sub

Sub Sort3()
    With ActiveWorkbook.Worksheets("Evaluation")
        .Range("A5:E20").Sort Key1:=.Range("A5")
    End With
End Sub

[Excelnoub]

Once again... lol

You have better my code.

Thank you Norie