Delete entire column if word "False" exists

I have the following code, but it takes longer than expected to run. Is there anyway to speed this up? I am not sure if autofilter is a option. I just want to search through range A16:Z16 and if the word "FALSE" exists delete the entire column. The word "TRUE" is the only other word that would exist in range A16:Z16

Sub Delete_Columns()
    With Worksheets("Accruals (2)").Range("A16:Z16")
        Set rng = Worksheets("Accruals (2)").Range("A16:Z16").Find(What:="FALSE", _
            LookAt:=xlWhole, MatchCase:=False)
        Do While Not rng Is Nothing
            rng.EntireColumn.Delete
            Set rng = .FindNext
        Loop
    End With
End Sub

Thank you

Efficient alternative:

Sub Delete_Columns()

    Dim rngFind As Range, rngDel As Range, sAdress As String

    With Worksheets("Accruals (2)").Range("A16:Z16")
        Set rngFind = .Find("FALSE")
        If Not rngFind Is Nothing Then
            sAdress = rngFind.Address
            Do
                If rngDel Is Nothing Then
                    Set rngDel = rngFind
                Else
                    Set rngDel = Application.Union(rngDel, rngFind)
                End If
                Set rngFind = .FindNext(rngFind)
            Loop While rngFind.Address <> sAdress
        End If
        If Not rngDel Is Nothing Then rngDel.EntireColumn.Delete
    End With
    
    Set rngFind = Nothing
    Set rngDel = Nothing
    
End Sub

Another:

Sub mikey3580()
With Range("A16:Z16")
    .Replace "FALSE", ""
    .SpecialCells(xlCellTypeBlanks).EntireColumn.Delete
End With
End Sub

Awesome!!! Thank you everyone!!!

@marreco. If you start another thread, I'd be glad to help you, but it is against Forum rules to post in another person's thread see Rule no 2.

2. Don't post a question in the thread of another member -- start your own. If you feel it's particularly relevant, provide a link to the other thread. You may include up to 3 links to other URLs in a single post, no more, so only link to the relevant pages.