Find multiple values in multiple ranges and produce results in a list

Hi Guys and Gals of Excel Forum, I have an interesting dilemma and I'm not quite sure where to start looking for answers (or even if there is an answer).

I'd like to carry out a find all search for occurrences of a combination of someones surname and post code (columns 12 & 13 respective) in the same worksheet, then for all occurrences of this combination I would like the result value of column 2 to be listed in a separate sheet.

i.e.e
Find = Jones & 18/11/1977

then say we find 4 results the list in another sheet to read

12345
23456
34567
45678

Is this do-able?

Just tried this and it works

Sub find_all()
Dim strName As String, strCode As String
Dim lngResultPoint As Long
Dim firstaddress As String
Dim c
        
    ''pointer to the first cell where the data will be written
    lngResultPoint = 1
    ''set the name being searched
    strName = "name to search"
    ''set the postcode
    strCode = "code to search"
    
    ActiveSheet.Range("L:L").Select
    
    With Selection
        Set c = .Find(What:=strName)
        If Not c Is Nothing Then
            firstaddress = c.Address
            Do
                If c.Offset(0, 1).Value = strCode Then
                    Worksheets("Results").Cells(lngResultPoint, 1).Value = c.Offset(0, -10).Value
                    lngResultPoint = lngResultPoint + 1
                End If
                
                Set c = .FindNext(c)
            Loop While c.Address <> firstaddress
        End If
    End With
        

End Sub

You Star, adapted for my purposes and works like a charm.

I'd be interested to know how to incorporate an additional search criteria though, say name, DOB and then post code (in that order)?

This is simple but it works

Sub find_all()
Dim strName As String, strCode As String, strDOB As String
Dim lngResultPoint As Long
Dim firstaddress As String
Dim c
        
    ''pointer to the first cell where the data will be written
    lngResultPoint = 1
    ''set the name being searched
    strName = "name to search"
    ''set the postcode
    strCode = "code to search"
    ''set the DOB
    strDOB = "DOB to search"
    
    ActiveSheet.Range("L:L").Select
    
    With Selection
        Set c = .Find(What:=strName)
        If Not c Is Nothing Then
            firstaddress = c.Address
            Do
                ''##A simple option is to check both criteria on the same line
                If c.Offset(0, 1).Value = strCode And c.Offset(0, 2).Value = strDOB Then ''Replace column 2 with one which should contain the DOB
                
                    Worksheets("Results").Cells(lngResultPoint, 1).Value = c.Offset(0, -10).Value
                    lngResultPoint = lngResultPoint + 1
                
                End If
                
                ''OR
                ''##you could nest them
                If c.Offset(0, 2).Value = strDOB Then ''Replace column 2 with one which should contain the DOB
                    If c.Offset(0, 1).Value = strCode Then
                    
                        Worksheets("Results").Cells(lngResultPoint, 1).Value = c.Offset(0, -10).Value
                        lngResultPoint = lngResultPoint + 1
                    
                    End If
                End If
                
                Set c = .FindNext(c)
            Loop While c.Address <> firstaddress
        End If
    End With
        

End Sub