Loop thru Charts in Workbook and Changing Chart 2/Error Handling

I've gotten further along as I continue to try to make this work.

Now I need to handle errors, but I'm not sure what types of errors I might come across.
It's possible a chart might be missing a data label to work with. What is best error handling method?

Looping code:

Sub MoveDataLabels2()

Dim ws As Worksheet
Dim objCht  As ChartObject


For Each ws In ActiveWorkbook.Worksheets

    For Each objCht In ActiveSheet.ChartObjects
        With objCht.Chart
                objCht.Activate
                   Call MoveDataLabels
        End With
    Next
    
    ActiveSheet.Range("AJ15").Select 'this is a place to break, don't really need it
    
Next ws

End Sub

Hi ker9,

Good progress.

Some of the problems include:
a. Data Series missing
b. Data point missing
c. Data label missing (if point is missing)
d. Data label text is not a number (improbable but possible)

Start deleting things one at a time until you get a runtime error. Then when you find which runtime errors you get you can process or ignore the possible errors.

For example you could use something like this as a starting point.

Sub MainRoutine()
    '...
    s1p1 = GetDataLabelAsLongInteger(6, 1)
    s1p2 = GetDataLabelAsLongInteger(6, 2) 
    '...
End Sub

Function GetDataLabelAsLongInteger(iSeriesNumber As Integer, iPointNumber As Integer) As Long

  Dim iError As Long

  On Error Resume Next
  GetDataLabelAsLongInteger = CLng(ActiveChart.SeriesCollection(iSeriesNumber).Points(iPointNumber).DataLabel.Text)
  
  iError = Err.Number
  Select Case iError
    
    Case 0
      'do nothing - no error
        
    Case 1004
      'Method 'SeriesCollection' of object '_Chart' Failed'
      'Stop, ignore, or perform automatic corrective action as required
      Debug.Print "Series " & iSeriesNumber & "  Point " & iPointNumber & "  Runtime Error " & iError
        
    Case Else
      'Stop, ignore, or perform automatic corrective action as required
      Debug.Print "Series " & iSeriesNumber & "  Point " & iPointNumber & "  Runtime Error " & iError
  End Select
    
  On Error GoTo 0

End Function

Lewis