Convert Embedded PowerPoint Chart to Excel

select the chart and then use the Edit Data in the Design tab of the Chart Tools contextual menu. You should then be able to copy/paste data from excel sheet

Sub X()

    Dim shpTemp As Shape
    Dim vntData As Variant
    Dim vntLabels As Variant
    Dim lngSeries As Long
    Dim lngItem As Long
    
    Set shpTemp = ActivePresentation.Slides(1).Shapes(1)
    
    With shpTemp.Chart
        For lngSeries = 1 To .SeriesCollection.Count
            Debug.Print .SeriesCollection(lngSeries).Name
            vntData = .SeriesCollection(lngSeries).Values
            vntLabels = .SeriesCollection(lngSeries).XValues
            
            For lngItem = LBound(vntData) To UBound(vntData)
                Debug.Print vntLabels(lngItem), vntData(lngItem)
            Next
        Next
    End With
    
End Sub

See if this in powerpoint reports information to the immediate window
update slide and shape references

Thanks Adam! I ran the macro, but I don't see any sort of output. Would you help me understand the logic behind the code below (looks like I need to go to coding school)?:

For lngItem = LBound(vntData) To UBound(vntData)
Debug.Print vntLabels(lngItem), vntData(lngItem)

Presentation1.zip

The information would have appeared in the Immediate window within the VBE. from pointpoint ALT+F11 CTRL+G

I modified the routine slightly to output to text file because the output was too much for immediate window, which is limited to 255 lines.

Sub X()

    Dim shpTemp As Shape
    Dim vntData As Variant
    Dim vntLabels As Variant
    Dim lngSeries As Long
    Dim lngItem As Long
    Dim intUnit As Integer
    
    intUnit = FreeFile
    Open "C:\temp\data.csv" For Output As intUnit
    
    Set shpTemp = ActivePresentation.Slides(1).Shapes(1)
    
    With shpTemp.Chart
        For lngSeries = 1 To .SeriesCollection.Count
            Write #intUnit, .SeriesCollection(lngSeries).Name
            vntData = .SeriesCollection(lngSeries).Values
            vntLabels = .SeriesCollection(lngSeries).XValues
            
            For lngItem = LBound(vntData) To UBound(vntData)
                Write #intUnit, , vntLabels(lngItem), vntData(lngItem)
            Next
        Next
    End With
    Close intUnit
End Sub

I then opened that file in excel and did some cut/paste to re arrange the data.

whose Adam ???

Simply changing the path would have done. No need to create a blank file as this will be overwritten rather than updated.

Open Activepresentation.path & "\data.csv" For Output As intUnit

this change will output in the same folder as the powerpoint file