trying to develop a spreadsheet that has an embedded keyword filter at top of page...

Tony,

Welcome to the forum!

Attached is an example workbook based on the criteria you described.
In cell B1 is a drop-down list of the column headers so you can choose which column you're filtering by.
In cell B2 you can type in what you want to filter for.

Changing either of those cells will trigger the worksheet_change event:

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim rngCol As Range
    Dim rngKey As Range
    Dim lCalc As Long
    Dim rngFilter As Range
    Dim LastRow As Long
    
    Set rngCol = Me.Range("B1")
    Set rngKey = Me.Range("B2")
    
    If Target.Address = rngCol.Address _
    Or Target.Address = rngKey.Address Then
        
        Me.AutoFilterMode = False
        If Len(rngCol.Value) = 0 Or Len(rngKey.Value) = 0 Then Exit Sub
        
        With Application
            lCalc = .Calculation
            .Calculation = xlCalculationManual
            .EnableEvents = False
            .ScreenUpdating = False
        End With
        On Error GoTo CleanExit
        
        LastRow = Me.Cells.Find("*", Me.Range("A1"), , , , xlPrevious).Row
        Set rngFilter = Me.Range("A4:E4").Find(rngCol.Value, , , xlWhole)
        Set rngFilter = Range(rngFilter, Me.Cells(LastRow, rngFilter.Column))
        rngFilter.AutoFilter 1, rngKey.Text
        
CleanExit:
        With Application
            .Calculation = lCalc
            .EnableEvents = True
            .ScreenUpdating = True
        End With
    End If
    
End Sub

Is something like that what you're looking for?