Need Conditional Text Display and Selection

This can be done with a worksheet_change event watching column A of your new sheet. As you type in zip codes in that column, it will add the matching dates to the right on the same row.

Option Explicit

Private Sub Worksheet_Change(ByVal target As Range)
Dim cell As Range, zipFIND As Range, zipFIRST As Range

For Each cell In target
    If Not Intersect(cell, Range("A:A")) Is Nothing Then
        Application.EnableEvents = False
        Range(cell.Offset(, 1), Cells(cell.Row, Columns.Count)).ClearContents
        If Len(cell) > 0 Then
            On Error Resume Next
            Set zipFIND = Sheets("JobAnalysis").Range("C:C").Find(cell.Value, _
                                LookIn:=xlValues, LookAt:=xlWhole)
            If Not zipFIND Is Nothing Then
                Set zipFIRST = zipFIND
                Do
                    Cells(cell.Row, Columns.Count).End(xlToLeft).Offset(, 1).Value = _
                                        zipFIND.Offset(, -1).Value
                    Set zipFIND = Sheets("JobAnalysis").Range("C:C").FindNext(zipFIND)
                Loop Until zipFIND.Address = zipFIRST.Address
                Columns.AutoFit
            End If
        End If
        Application.EnableEvents = True
    End If
Next cell
End Sub

Originally Posted by JBeaucaire

This can be done with a worksheet_change event watching column A of your new sheet. As you type in zip codes in that column, it will add the matching dates to the right on the same row.

Option Explicit

Private Sub Worksheet_Change(ByVal target As Range)
Dim cell As Range, zipFIND As Range, zipFIRST As Range

For Each cell In target
    If Not Intersect(cell, Range("A:A")) Is Nothing Then
        Application.EnableEvents = False
        Range(cell.Offset(, 1), Cells(cell.Row, Columns.Count)).ClearContents
        If Len(cell) > 0 Then
            On Error Resume Next
            Set zipFIND = Sheets("JobAnalysis").Range("C:C").Find(cell.Value, _
                                LookIn:=xlValues, LookAt:=xlWhole)
            If Not zipFIND Is Nothing Then
                Set zipFIRST = zipFIND
                Do
                    Cells(cell.Row, Columns.Count).End(xlToLeft).Offset(, 1).Value = _
                                        zipFIND.Offset(, -1).Value
                    Set zipFIND = Sheets("JobAnalysis").Range("C:C").FindNext(zipFIND)
                Loop Until zipFIND.Address = zipFIRST.Address
                Columns.AutoFit
            End If
        End If
        Application.EnableEvents = True
    End If
Next cell
End Sub

Thanks for the solution

It really works, but how do i find a match for the Alpha-numerically closest ZIP code and its corresdponding date.
For example, I am looking for code K2P 1N1 and the date for this particular code is not present in the list.
Then, it should display the dates for the alpha-numerically closest match, ie, any of the codes in K2P series.

Thanks

1) please don't quote my entire post into yours.

2) Add this, if there is no "exact match" to the zip entered, it will search again using only the first 3 characters.

Option Explicit

Private Sub Worksheet_Change(ByVal target As Range)
Dim cell As Range, zipFIND As Range, zipFIRST As Range

For Each cell In target
    If Not Intersect(cell, Range("A:A")) Is Nothing Then
        Application.EnableEvents = False
        Range(cell.Offset(, 1), Cells(cell.Row, Columns.Count)).ClearContents
        If Len(cell) > 0 Then
            On Error Resume Next
            Set zipFIND = Sheets("JobAnalysis").Range("C:C").Find(cell.Value, _
                                LookIn:=xlValues, LookAt:=xlWhole)
            If zipFIND Is Nothing Then Set zipFIND = _
                Sheets("JobAnalysis").Range("C:C").Find(Left(cell.Value, 3), _
                                LookIn:=xlValues, LookAt:=xlPart)
            If Not zipFIND Is Nothing Then
                Set zipFIRST = zipFIND
                Do
                    Cells(cell.Row, Columns.Count).End(xlToLeft).Offset(, 1).Value = _
                                        zipFIND.Offset(, -1).Value
                    Set zipFIND = Sheets("JobAnalysis").Range("C:C").FindNext(zipFIND)
                Loop Until zipFIND.Address = zipFIRST.Address
                Columns.AutoFit
            End If
        End If
        Application.EnableEvents = True
    End If
Next cell
End Sub

Glad to help.

If that takes care of your need, please click Thread Tools above your first post and mark this thread as SOLVED.