Create worksheets based on template for list of names

I have a list of company names in Column A, Sheet1. I have a template on Sheet2

I would like to create a new worksheet for each company name in ColumnA, Sheet1 based on the template in Sheet2.

Please see attached.

Xx7,

Here's one way to do it:

Sub tgr()
    
    Dim wsSum As Worksheet: Set wsSum = Sheets(1)
    Dim wsTmp As Worksheet: Set wsTmp = Sheets(2)
    Dim NameCell As Range
    
    Application.ScreenUpdating = False
    
    For Each NameCell In Intersect(wsSum.UsedRange, wsSum.Columns("A"))
        If Trim(NameCell.Text) <> vbNullString And ValidSheetName(Trim(NameCell.Text)) Then
            wsTmp.Copy after:=Sheets(Sheets.Count)
            ActiveSheet.Name = Trim(NameCell.Text)
        End If
    Next NameCell
    wsSum.Select
    
    Application.ScreenUpdating = True
    
End Sub

Private Function ValidSheetName(strName As String) As Boolean
    
    Dim ws As Worksheet
    Dim i As Integer
    
    If Len(strName) > 31 Then
        MsgBox "Sheet name """ & strName & """ exceeds 31 characters.", , "Invalid Sheet Name"
        Exit Function
    End If
    
    For i = 1 To 7
        If InStr(strName, Mid(":\/?*[]", i, 1)) > 0 Then
            MsgBox "Invalid character in """ & strName & """" & Chr(10) & Chr(10) & "The following are invalid characters:" & Chr(10) & ": \ / ? * [ ]", , "Invalid Sheet Name"
            Exit Function
        End If
    Next i
    
    On Error GoTo ValidName
    Set ws = Sheets(strName)
    MsgBox "Sheet name """ & strName & """ already exists", , "Invalid Sheet Name"
    Exit Function
    
ValidName:
    ValidSheetName = True
    
End Function