Delete Rows Based on Dates, etc.

Try as a test...

Sub FilterDelete()
    With Range("C1", Range("C" & Rows.Count).End(xlUp))
        .AutoFilter field:=1, Criteria1:="-"
        .Offset(1).EntireRow.Delete
        .AutoFilter
    End With
End Sub

Okay if I understand correctly, if Jeff is completely blank for the entire month you want it deleted, but if John has values for the month yet some days and blank you still want those intact?

Sorry I missed that part the first time.

Give this a test. It utilizes Sheet3 to get a unique count of names and whether or not the total volumn is 0. If 0 then that person is deleted from Sheet1 and if not 0 then kept.

Sub Macro1()
    Dim wsSrc As Worksheet: Set wsSrc = Sheets("Sheet1")
    Dim wsDest As Worksheet: Set wsDest = Sheets("Sheet3")
    Dim i As Long
    Dim LR As Long
    With wsSrc
        .Columns("A:A").AdvancedFilter Action:=xlFilterCopy, _
            CopyToRange:=wsDest.Range("A1"), Unique:=True
    End With
    With wsDest
        .Range("B2:B" & .Range("A" & .Rows.Count).End(xlUp).Row).FormulaR1C1 _
            = "=SUMIF(Sheet1!R2C1:R151C1,RC[-1],Sheet1!R2C3:R151C3)"
        LR = .Range("A" & .Rows.Count).End(xlUp).Row
        For i = 2 To LR
            If .Range("B" & i).Value = 0 Then
                With wsSrc
                    With .Range("A1", .Range("A" & .Rows.Count).End(xlUp))
                        .AutoFilter field:=1, Criteria1:=wsDest.Range("A" & i).Value
                        .Offset(1).EntireRow.Delete
                        .AutoFilter
                    End With
                End With
            End If
        Next i
    End With
End Sub

No worries the confusion was on my part...I often read too fast.

If you are satisfied with the answer provided, please don’t forget to mark the thread as solved.

How to mark a thread Solved
Go to the first post
Select
-- Edit
-- Go Advanced
-- Below the word Title you will see a dropdown with the word No prefix
-- Update to Solved and then select Save

I'm sorry that is my fault. I forgot to build in the LR variable for the Sumif.

I'll post a revision in a few

Try...

Sub Macro1()
    Dim wsSrc As Worksheet: Set wsSrc = Sheets("Sheet1")
    Dim wsDest As Worksheet: Set wsDest = Sheets("Sheet3")
    Dim i As Long
    Dim LR As Long
    Dim LR1 As Long
    Application.ScreenUpdating = False
    With wsSrc
        .Columns("A:A").AdvancedFilter Action:=xlFilterCopy, _
            CopyToRange:=wsDest.Range("A1"), Unique:=True
    End With
    With wsDest
        LR1 = wsSrc.Range("A" & .Rows.Count).End(xlUp).Row
        .Range("B2:B" & .Range("A" & .Rows.Count).End(xlUp).Row).FormulaR1C1 _
            = "=SUMIF(Sheet1!R2C1:R" & LR1 & "C1,RC[-1],Sheet1!R2C3:R" & LR1 & "C3)"
        LR = .Range("A" & .Rows.Count).End(xlUp).Row
        For i = 2 To LR
            If .Range("B" & i).Value = 0 Then
                With wsSrc
                    With .Range("A1", .Range("A" & .Rows.Count).End(xlUp))
                        .AutoFilter field:=1, Criteria1:=wsDest.Range("A" & i).Value
                        .Offset(1).EntireRow.Delete
                        .AutoFilter
                    End With
                End With
            End If
        Next i
    End With
    Application.ScreenUpdating = True
End Sub

You're welcome

Please don't forget to mark your thread as solved