Summing in groups based on specific criteria

Hey there, I ran into this forum and wanted to ask a question!
I got a question about flexible sommations.

Lets say I have clusters of the following format;

K_____________ N
11144_____________ 192
111555767_____________1,78
WE11231_____________ 63,8
WE123123_____________1620
EW12312_____________ 2
RR123____________1590
DC11112231_____________
ABa123123_____________
AOW123123123_____________
DC9988 _____________

The amount of lines between two DCxxxx numbers can fluctuate between 1 and 99, codes in column K are unique. K and N are vital.

If a line starts with DC, the lines below are part of the DC ( in the example DC11111A)
group untill a new DCxx ( in the example DC11112231) comes up. Then the following lines will be the base of the new DC number (DC11112231).

How can I make it cluster the lines, giving a sommation for each DC number?

ultimatly displaying;

DC11111A 3469,58
DC11112231 0
DC9988 0

Thanks in advance for any support!

Your sample does not show a DC11111A.... but assuming your data is in K2:K11 and N2:N11

then in a new column at row 2 enter:

=IF(LEFT(K2;2)="DC";SUM(N2:INDEX(N3:N$11;MATCH("DC*";K3:K$11;0)));"")

copied down.

If you want to consolidate then in another new column enter:

=LOOKUP(REPT("z";255);CHOOSE({1;2};"";INDEX($K$2:$K$11;SMALL(IF(ISNUMBER($O$2:$O$11);ROW($K$2:$K$11)-ROW($K$2)+1);ROWS($A$1:$A1)))))

where O2:O11 is where you put the first formula. Then confirm this formula with CTRL+SHIFT+ENTER not just ENTER and copy down.

Then in next column, assuming you put the above formula in Q2 down.

=IF(Q2="";"";SUMIF($K$2:$K$11;Q2;$O$2:$O$11))

copied down.

You may need to translate the functions.....

I am sorry for the late reply, but it works like a charm! Awesome that you took the time and effort to help me out!