Adding the same header row to multiple spreadsheets

Hello everyone

I have several data files (each in XLS format) that are the output of an experiment. Unfortunately, the files were created (in Matlab) without header rows, so it's hard to keep track of what each of the 10+ columns mean. I would therefore like to add a header row (the same header row) to each one of these spreadsheets, but I cannot figure out a way to do this automatically. I have hundreds of data files, and opening each one of them, pasting the header row and saving would take a lot of time.

Can anyone suggest a way to do this? Anticipated thanks for any replies!

Also, I really need to be able to do this quite soon, therefore apologies for cross-posting this on another Excel forum as well (will mark both as solved when they are)

Try this

Select and copy the headers you want to replicate.

Group the sheets, you want to add the headers.
Click on the first of the sheet tabs, then hold down the Shift key while you click on the other tabs to be included.

Press Enter

I was hoping to find a way to do this without using a macro, but I doubt this is possible, anyway I managed to do this in the meantime, Hans from Microsoft Answers kindly provided the code for the following macro which does just what I was asking for:

Sub SetHeaderRow()
  Dim strPath As String
  Dim strFile As String
  Dim wbk As Workbook
  Dim wsh As Worksheet
  ' Let user select a folder
  With Application.FileDialog(msoFileDialogFolderPicker)
    If .Show Then
      strPath = .SelectedItems(1)
    Else
      MsgBox "No folder selected", vbInformation
      Exit Sub
    End If
  End With
  Application.ScreenUpdating = False
  If Right(strPath, 1) <> "\" Then
    strPath = strPath & "\"
  End If
  ' Loop through the Excel workbooks in the folder
  strFile = Dir(strPath & "*.xls*")
  Do While strFile <> ""
    ' Open the workbook
    Set wbk = Workbooks.Open(Filename:=strPath & strFile, AddToMRU:=False)
    ' Loop through the worksheets in the workbook
    For Each wsh In wbk.Worksheets
      ' Insert row
      wsh.Range("A1").EntireRow.Insert
      ' Set some values
      wsh.Range("A1") = "This"
      wsh.Range("B1") = "That"
      ' ...
      wsh.Range("L1") = "Finally"
    Next wsh
    ' Save and close the workbook
    wbk.Close SaveChanges:=True
    ' On to the next
    strFile = Dir
  Loop
  Application.ScreenUpdating = True
End Sub

Thanks again Marcol, and again apologies for the cross-posting.