extracting info to another worksheet

Try this:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
Dim NR As Long

For Each Cell In Target
    If Not Intersect(Cell, Range("C3:C250,I3:I250")) Is Nothing Then
        With Cell.Offset(, 1)
            .Value = Time
            .EntireColumn.AutoFit
        End With
    ElseIf Cell.Column = 8 And Cell = "Closed" Then
        Cell.Offset(, 2) = Time
        With Sheets("Sheet3")
            NR = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            .Range("A" & NR).Value = Range("E" & Cell.Row).Value
            .Range("B" & NR).Resize(1, 2).Value = _
                Range("G" & Cell.Row).Resize(1, 2).Value
        End With
    End If
Next Cell

End Sub

This method allows you to change multiple cells at once and it will process them all correctly, instead of just exiting the sub.

Thanks JBeaucaire,

Would it be possible to explain the lines:

NR = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            .Range("A" & NR).Value = Range("E" & Cell.Row).Value
            .Range("B" & NR).Resize(1, 2).Value = _
                Range("G" & Cell.Row).Resize(1, 2).Value

Sorry to bother you, but I want to understand whats actually asking.

Cheers,
Pete

Also, why is this line required?

Cell.Offset(, 2) = Time

Cheers

Looking at your sheet again, I noticed a problem formula in column I. The formula uses the TODAY() function to display a date. You do realize that each time you open the sheet all those formulas will update to display today's date, not the first day it was resolved?

As such, since you're using VBA anyway, I'd remove the formula and let VBA enter the date, too. It's been added here along with the comments you've requested:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
Dim NR As Long

For Each Cell In Target
    If Not Intersect(Cell, Range("C:C,I:I")) Is Nothing Then
        With Cell.Offset(, 1)       'using the cell to the right...
            .Value = Time           '...add the time
            .EntireColumn.AutoFit   'autofit that column
        End With
    ElseIf Cell.Column = 8 And Cell = "Closed" Then
        Cell.Offset(, 1) = Date     'add date one cell to the right, in column 9
        Cell.Offset(, 2) = Time     'add time two cells to the right, in column 10
        With Sheets("Sheet3")
            'find the next empty row on sheet3
            NR = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            'put the value from A into sheet3 column A
            .Range("A" & NR).Value = Range("E" & Cell.Row).Value
            'put the values from G:H into sheet3 columns B:C
            .Range("B" & NR).Resize(1, 2).Value = _
                Range("G" & Cell.Row).Resize(1, 2).Value
        End With
    End If
Next Cell

End Sub

What/When/How do you see this movement being triggered?

I would use a Worksheet_Activate on this "other sheet" that does an AutoFilter on the main sheet for the Faults and then copies them as a whole to the top of the "other sheet", deleting them from the main sheet, then turning off the AutoFilter. So any time you want to "move" the fault, you would need only to activate this "other sheet".

Create a modified workbook and see if you can get an autofilter to copy the rows, we can tweak that together to make it cut/delete from the main sheet.

The worksheet change event I gave you didn't include making more changes to the active sheet. When you do that, you have to turn off macros first, else the ws_change macro can keep triggering itself over and over...could be problematic.

My edits on your updated version of that macro:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
Dim NR As Long
Application.EnableEvents = False

For Each Cell In Target
    If Not Intersect(Cell, Range("C:C,I:I")) Is Nothing Then
        With Cell.Offset(, 1)       'using the cell to the right...
            .Value = Time           '...add the time
            .EntireColumn.AutoFit   'autofit that column
        End With
    ElseIf Cell.Column = 8 And Cell = "Closed" Then
        Cell.Offset(, 1) = Date     'add date one cell to the right, in column 9
        Cell.Offset(, 2) = Time     'add time two cells to the right, in column 10
        With Sheets("Summary Sheet")
            'find the next empty row on sheet3
            NR = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            'put the value from A into sheet3 column A
            .Range("A" & NR).Value = Range("C" & Cell.Row).Value
            'put the values from G:H into sheet3 columns B:C
            .Range("B" & NR).Resize(1, 2).Value = _
                Range("E" & Cell.Row).Resize(1, 2).Value
            .Range("D" & NR).Value = Range("I" & Cell.Row).Value
        End With
    ElseIf Cell.Column = 8 And Cell = "Open" Or Cell = "In Progress" Then
        Cell.Offset(, 1).Resize(1, 2) = "N/A"
    ElseIf Cell.Column = 8 And Cell = "" Then
        Cell.Offset(, 1).Resize(1, 2) = ""
    End If
    
Next Cell

Application.EnableEvents = True
End Sub

Other macro edits:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Cells.Count > 1 Then Exit Sub
    If Target.Column = 3 Then
        Calendar1.Left = Target.Left + Target.Width - Calendar1.Width
        Calendar1.Top = Target.Top + Target.Height
        Calendar1.Visible = True
    ' select Today's date in the Calendar
        Calendar1.Value = Date
    ElseIf Calendar1.Visible Then Calendar1.Visible = False
    End If
End Sub

Sub DeleteLine()

'   clear date, severity, comments, workorder, flags
    ActiveCell.Resize(1, 9).ClearContents

End Sub

Sub DeleteEntireRow()

' Delete Date, car num, oscar pos, actual pos,temp,severity,hbd pos,loaded empty,sap,notify num,car tsl
    ActiveCell.Resize(1, 11).Delete Shift:=xlUp
    
End Sub

Here's more, this adds moving the row to Removed Faults when it's set as "closed".

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cell As Range
Dim NR As Long
Application.EnableEvents = False
For Each Cell In Target
    If Not Intersect(Cell, Range("C:C,I:I")) Is Nothing Then
        With Cell.Offset(, 1)       'using the cell to the right...
            .Value = Time           '...add the time
            .EntireColumn.AutoFit   'autofit that column
        End With
    ElseIf Cell.Column = 8 And Cell = "Closed" Then
        Cell.Offset(, 1) = Date     'add date one cell to the right, in column 9
        Cell.Offset(, 2) = Time     'add time two cells to the right, in column 10
        With Sheets("Summary Sheet")
            'find the next empty row on sheet3
            NR = .Range("A" & .Rows.Count).End(xlUp).Row + 1
            'put the value from A into sheet3 column A
            .Range("A" & NR).Value = Range("C" & Cell.Row).Value
            'put the values from G:H into sheet3 columns B:C
            .Range("B" & NR).Resize(1, 2).Value = _
                Range("E" & Cell.Row).Resize(1, 2).Value
            .Range("D" & NR).Value = Range("I" & Cell.Row).Value
        End With
        With Sheets("Removed Faults")
            .Range("B3:L3").Insert xlShiftDown
            Range("B" & Cell.Row).Resize(1, 11).Copy
            .Range("B3").PasteSpecial xlPasteValues
            .Range("B3").PasteSpecial xlPasteFormats
            Range("B" & Cell.Row).Resize(1, 11).Delete xlShiftUp
        End With
        Range("B4", Range("B" & Rows.Count).End(xlUp)).FormulaR1C1 = _
            "=IF(R[-1]C12=""Kris Kilian"",ROW(R[-2]C2),IF(R[-1]C12=""Vladimir Mazur"",ROW(R[-2]C2),IF(R[-1]C12=""Mindy Donnelly"",ROW(R[-2]C2),IF(R[-1]C12=""Harun Trefry"",ROW(R[-2]C2),IF(R[-1]C12="""","""",IF(R[-1]C12=""Other"",ROW(R[-2]C2)))))))"

    ElseIf Cell.Column = 8 And Cell = "Open" Or Cell = "In Progress" Then
        Cell.Offset(, 1).Resize(1, 2) = "N/A"
    ElseIf Cell.Column = 8 And Cell = "" Then
        Cell.Offset(, 1).Resize(1, 2) = ""
    End If
    
Next Cell

Application.EnableEvents = True
End Sub