"convert" data with logfile structure to spreadsheet structure

Hi folks.

This must be one of the top 10 classic Excel problems:
How to automate the import of non-table-data into an Excel table?

I have a logfile listing my mobile phone's calls and SMS. Each entry is separated with a "----------" line.

----------
TYPE=CALL
NUMBER=123456789
NAME=john
CALLTYPEV2=2
OTHERPARTYTYPE=2
ENDCAUSE=1
ENDCAUSESIP=-1
ENDCAUSESTRING=Called party ended the call
ENDLOCATION=2
CALLSTARTTIME=2009-6-29 17:56:30
CONNSTARTTIME=2009-6-29 17:56:36
CALLENDTIME=2009-6-29 18:1:48
DURATION=0:5:12
NEWVOICEMAIL=NO
----------
TYPE=CALL
NUMBER=123456777
NAME=james
CALLTYPEV2=2
OTHERPARTYTYPE=2
ENDCAUSE=1
ENDCAUSESIP=-1
ENDCAUSESTRING=Called party ended the call
ENDLOCATION=2
CALLSTARTTIME=2009-7-8 12:52:18
CONNSTARTTIME=2009-7-8 12:52:38
CALLENDTIME=2009-7-8 12:54:36
DURATION=0:1:58
NEWVOICEMAIL=NO
----------

Now what I want to do is import all the data into a table.
The result should look like the attached image.

What must I do?
Thank you so much.

Try this:

Option Explicit

Sub ImportAndFormat()
Dim fName As String
Dim LR As Long

'Select an import file
    With Application.FileDialog(msoFileDialogOpen)
        .InitialFileName = "C:\2011\Import\"
        .AllowMultiSelect = False
        .Filters.Add "Text Files", "*.txt", 1  'default
        .Filters.Add "All Files", "*.*"        'everything
        .Show
        If .SelectedItems.Count > 0 Then fName = .SelectedItems(1) Else Exit Sub
    End With
'Import data
    ActiveWorkbook.Worksheets.Add
    With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & fName, _
        Destination:=Range("A1"))
        .Name = "CellCalls"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 437
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = True
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = False
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = Array(1, 1)
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False
    End With

'Format new table
    Range("B1") = "TYPE"
    Range("C1") = "NUMBER"
    Range("D1") = "NAME"
    Range("E1") = "CALLTYPEV2"
    Range("F1") = "OTHERPARTYTYPE"
    Range("G1") = "ENDCAUSE"
    Range("H1") = "ENDCAUSESIP"
    Range("I1") = "ENDCAUSESTRING"
    Range("J1") = "ENDLOCATION"
    Range("K1") = "CALLSTARTTIME"
    Range("L1") = "CONNSTARTTIME"
    Range("M1") = "CALLENDTIME"
    Range("N1") = "DURATION"
    Range("O1") = "NEWVOICEMAIL"

    LR = Int(Range("A" & Rows.Count).End(xlUp).Row / 15)
    With Range("B2:O" & LR)
        .FormulaR1C1 = _
            "=SUBSTITUTE(INDEX(C1, ((ROW(R[-1]C[-1])-1)*15)+COLUMN(R[-1]C)),R1C&""="","""")"
        .Value = .Value
    End With
    
    Range("A:A").Delete xlShiftToLeft
    Columns.AutoFit
End Sub

Edit the InitialFilename string to the path where your files are most likely to be.

Also, I set the filter to text files, you can edit that to whatever extension your data file usually has.

like this with functions
i havent bothered to hide #VALUE! but it is easily done if required

thank you JBeaucaire and martindwilson.
you really had clever ideas. As far as I can see this does exactly what I need.
I always mark as "solved".
Just give me a little time to look through your instructions and help.
Thank you.

(EDIT: deleted some confused stuff I wrote before putting my specs on :-)

My macro is actually creating the table for you using worksheet functions, I just put the formula into a macro.

This is the formula I put in B2 and copy down and across as far as needed, then I remove the formulas and flatten the values:

=SUBSTITUTE(INDEX($A:$A, ((ROW(A1)-1)*15)+COLUMN(B1)),B$1&"=","")

Try that...just put your data in column A, then that formula in column B starting at B2, then copy the cell...the rest of the data reformats.

Lastly, the macro version just deletes the column A raw data.

thank you! I gave rep points to both of you.

It will take me a bit to familiarize myself with the concepts, but I will definitely give feedback here once I have figured it out. Thank you so much.

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.