Excel 2007 : Copying text of cell A to cell B, depending on value of cell C?

**robbyvegas** · 08-18-2010, 12:16 AM

I'd like to be able to add the text of cell A in worksheet A, to cell B (read concatenate to text already in cell B) in worksheet B, when cell C in worksheet B = a specific value.

If the above description is as clear as mud, let me know and I'll see if I can do better.

Thanks,

Rob

**DonkeyOte** · 08-18-2010, 02:08 AM

The key part is "concatenate to text already in cell B" - this would require VBA.

The next question is then how the value in cell C is altered ? Is it manual entry or formula result ? If it is a formula please outline the formula itself such that we can work back to the first manual precedent.

**robbyvegas** · 08-18-2010, 02:21 AM

Originally Posted by DonkeyOte

The key part is "concatenate to text already in cell B" - this would require VBA.

Sigh. I knew I should have learned VBA when I had the time. Sadly, I'm far to busy to really learn it now. The value in cell C is a manual entry string. How complex is the requisite VBA? I can generally understand code if someone can start me in the right direction. I'd really appreciate all the help I can get.

Thanks again,

Rob

**DonkeyOte** · 08-18-2010, 02:29 AM

You would use the Change event of the parent sheet object - test to see if the cells altered are in Column C and if so what their respective values are - in turn adjusting B as stated.

For a generic and totally untested example:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngInterest As Range, rngCell As Range
    On Error GoTo ExitPoint
    Application.EnableEvents = False
    Set rngInterest = Intersect(Target,Columns("C"))
    If Not rngInterest Is Nothing Then
        For Each rngCell In rngInterest.Cells
            If UCase(rngCell.Value) = "X" Then
                With rngCell.Offset(,-1)
                    .Value = LTrim(.Value & " " & .Offset(,-1).Value)
                End With
            End If
        Next rngCell
    End If
ExitPoint:
    Application.EnableEvents = True
End Sub

to insert the above right click on sheet to which the above is to be applied - select View Code and paste above into resulting window.
Thereafter in a macro enabled file altering value in C to "X" should adjust the string in B such that it appends the present value in A to it.