Excel 2007 : Macro - loop slows down

ExpRate is undefined.

As a row variable, i should be declared as a Long, not an Integer.

You're writing to the statusbar in every loop iteration. You could do it every 10th or 100th iteration.

If your changes are causing portions of the workbook to recalculate, you should turn calculation off and calculate only whatever portion you need to within the loop.

You make repeated and unnecessary references to ThisWorkbook, which could be eliminated with a With statement or setting some new object variables.

You've set the three range variables to the same range -- why?

So there's a lot you could do, but I can't tell what the whole procedure is doing, so it's hard to be specific.

How big is range ER?

Without seeing the workbook, or knowing if a loop is even necessary, ...

Option Explicit

Sub SG()
    Dim rExp        As Range
'    Dim rCom        As Range
'    Dim rPrm        As Range
    Dim rInp        As Range
    Dim rERC        As Range
    Dim rERP        As Range

    Dim iRow        As Long
    Dim nRow        As Long

    With ThisWorkbook
        Set rExp = .Worksheets("MGN").Range("ER")
'        Set rCom = .Worksheets("MGN").Range("ER")
'        Set rPrm = .Worksheets("MGN").Range("ER")
        Set rInp = .Worksheets("Input").Range("MacroInput")
        Set rERC = .Worksheets("MGN Detail").Range("ERCopyRange")
        Set rERP = .Worksheets("MGN Detail").Range("ERPasteTarget")
    End With

    nRow = rExp.Rows.Count

    With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
        rInp.ClearContents

        For iRow = 1 To rExp.Rows.Count
            If iRow Mod 100 = 0 Then Application.StatusBar = "Row " & iRow & " of " & nRow
            rInp.Value = rExp(iRow, 1).Value
            ' calculate something here if necessary
            rERP.Offset(iRow - 1).Value = rERC.Value
        Next iRow

        .ScreenUpdating = True
        .Calculation = xlCalculationAutomatic
    End With
End Sub

Possibly something like:

ThisWorkbook.Sheets("MGN Detail").Range("ERCopyRange").Calculate

That exact syntax will work. It doesn't turn calculation back on for that range, but it does calculate it once with all dependencies. However, what you'd actually do, for the reasons previously described, is

rERC.Calculate

See Help for the Calculate method.

The code doesn't truncate anything. Change the formatting to General.