Excel 2007 : Sorting and updating list in multiple tabs

All of that sounds like a macro of some kind. I'd need to see this workbook to suggest anything specific.

A worksheet_change event built into the Master can take care of this.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
'Jerry Beaucaire    5/18/2010
'Items added on List sheet are added to all other sheets
'All sheets are sorted automatically
Dim cell    As Range
Dim rFind   As Range
Dim sortRNG As Range
Dim ws      As Worksheet
Dim LR      As Long
Dim LC      As Long

On Error Resume Next
For Each cell In Target
    If Not Intersect(cell, Range("B4:B" & Rows.Count)) _
        Is Nothing And cell.Value <> "" Then
        For Each ws In Worksheets
            If ws.Name <> Me.Name Then
                Set rFind = ws.Range("B:B").Find(What:=cell, After:=ws.Range("B1"), _
                    LookIn:=xlFormulas, LookAt:=xlWhole, SearchOrder:=xlByRows, _
                    SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
                If rFind Is Nothing Then
                    ws.Range("B" & Rows.Count).End(xlUp).Offset(1, 0).Value = _
                        Application.WorksheetFunction.Proper(cell)
                    LR = ws.Range("B" & ws.Rows.Count).End(xlUp).Row
                    LC = ws.Cells(4, Columns.Count).End(xlToLeft).Column
                    ws.Range("B4:BB" & LR).Sort Key1:=ws.Range("B5"), _
                        Order1:=xlAscending, Header:=xlYes, _
                        OrderCustom:=1, MatchCase:=False, _
                        Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
                Else
                    Set rFind = Nothing
                End If
            End If
        Next ws
        Application.EnableEvents = False
        Range("B4:B" & LR).Sort Key1:=Range("B4"), Order1:=xlAscending, _
            Header:=xlYes, OrderCustom:=1, MatchCase:=False, _
            Orientation:=xlTopToBottom, DataOption1:=xlSortNormal
        Application.EnableEvents = True
    End If
Next cell

End Sub

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.