Automatically updating date fields

HI
I've inherited a set of UNIX regresion test suites (120+, slowly increrasing) held as excel spreadsheets. These sheets are ftped to Unix where a perl script converts then to various application specific functions. These spreadsheet have a lot of date fields, which need to be updated, the instructions that I have is to open/save/close all the spreadsheets before each run, which is about once a month.
Is there any way of updating the date fields in the spreadsheet without having to open/save/close each spreadsheet?
EG. a command line option, or would is need something to maybe open/save/close these spreadsheets automatically ( another spreadsheet ?)
Thanks in anticipation

Highoaks:

Maybe you could give this a try. First on some backup copies of your files. Place them in a separate directory to be sure.

Sub open_all_files_and_save()
'mypath is variant because it can be boolean to when no file is chosen
Dim mywb As Workbook, newwb As Workbook, myfile As String, mypath
Dim myloop As Long, newpath As String
'set your activeworkbook
Set mywb = ActiveWorkbook
'choose one file in the directory that you want
'and select open
mypath = Application.GetOpenFilename("Excel files (*.xls; *.xlsx),*.xls;*.xlsx")
'if you choose cancel, this routine will just quit with no error
'notification anymore
If mypath = False Then Exit Sub
'we build the path from this file by looping through the whole
'name and substract the last array element
For myloop = LBound(Split(mypath, "\")) To UBound(Split(mypath, "\")) - 1
    newpath = newpath & Split(mypath, "\")(myloop) & "\"
Next myloop
'we want to loop through all the files in the directory
'that you have chosen. I assume they are all xls files
myfile = Dir(newpath & "*.xls")
Do While myfile <> vbNullString
    Set newwb = Workbooks.Open(newpath & myfile)
    newwb.Save
    newwb.Close False
    'prepare for next file
    myfile = Dir
Loop
MsgBox "Files in ..." & vbCrLf & newpath & vbCrLf & _
        "are updated and saved.", vbInformation
End Sub

Charlize