Count_Question

**excelhelp18** · 02-10-2010, 04:26 AM

Hi,

Need your help on the following:

I have a set of data on sites operating with different volts. volts are between 24 & 48.

I have to perform set of criteria's calculation to understand the data more deeply. I have attached a sample set of data but in reality I have around 10000 rows of same.

Criteria's I want to build are:
Sites Count With > 1 24V
Sites Count With > 2 24V
Sites Count With > 3 24V
Sites Count With > 4 24V

Sites Count With > 1 48V
Sites Count With > 2 48V
Sites Count With > 3 48V
Sites Count With > 4 48V

and some other more...I have given the desired output view also.. I need to have same output through some excel formulea. Right now, I have calculated this manually.

Thanks a lot in advance.

**Simon Lloyd** · 02-10-2010, 04:30 AM

Could you possibly attach a workbook that has been saved down to xl97-2003 ?, i'd like to take a look but don't have xl2010 on this machine.

**excelhelp18** · 02-10-2010, 04:39 AM

here you go.. attached is 2003 version...

**DonkeyOte** · 02-10-2010, 05:10 AM

One route...

First create a key, concatenating each Volt recording, eg:

G2: =":"&B2&"::"&C2&"::"&D2&"::"&E2&"::"&F2&"::"&":"
copied down to G15

Then to allow for relatively consistent formulae...

L2:L5 enter 2 to 5 respectively
repeat for L7:L10 & L12:L15

Into M2:M5 enter 24
Into M7:M10 enter 48

With the above in place we can proceed to summarise...

I2: =COUNTIF($G$2:$G$15,"*:"&SUBSTITUTE(TRIM(REPT(" "&$M2&" ",$L2))," ",":*:")&":*")
copied to I5

I2:I5 copied to I7:I10

then

J12: =SUMPRODUCT(--(((LEN($G$2:$G$15)-LEN(SUBSTITUTE(SUBSTITUTE($G$2:$G$15,24,""),48,"")))/2)>=$L12))
copied down to J15

then

J17: =SUMPRODUCT(--(LEN($G$2:$G$15)<>LEN(SUBSTITUTE(SUBSTITUTE($G$2:$G$15,24,""),48,""))))

J18: =COUNTIF($G$2:$G$15,REPT(":",12))

J19: =COUNT($B$2:$F$15)
or
J19: =SUMPRODUCT(LEN($G$2:$G$15)-LEN(SUBSTITUTE(SUBSTITUTE($G$2:$G$15,24,""),48,"")))/2
(obviously first option is the better!)

Attached is above in working form...

**excelhelp18** · 02-10-2010, 05:41 AM

hi,

Thanks for the prompt reply. but this seems to be dependent on concatenation part and I dont have that comfort to increase the columns...The data set is very huge and no of variables are multiples..this does not seems to be feasible to me... Can I have some other short and non-dependent formulae to achieve the same...

Thanks a lot

**DonkeyOte** · 02-10-2010, 05:59 AM

A single cell formula devoid of helpers would IMO require use of a Volatile SUMPRODUCT / Array approach and if as you say the dataset is vast that will pretty much lead to your file imploding upon itself in terms of calculation times.

If you don't want to use Concatenation (too many columns) then another (far) simpler route would be to use three calculations adjacent to each row, namely:

=COUNTIF($B2:$F2,24)
=COUNTIF($B2:$F2,48)
=COUNT($B2:$F2) - (or sum of prior 2 calcs)

returning count of 24, 48 and any of 24/48 respectively

From these three cells you can determine the remainder for yourself I think.
(this is a much better route than that advised previously)

If you can't do that then I'm afraid you should really be looking at User Defined Functions (VBA) or simply conduct the calcs on another sheet where you do have space.

Regardless it is important you accept that XL is not a purpose built data warehouse - if you have mass data as implied then you should be using one to store your data and using SQL to analyse.