Copy formula with unchanged references

You know - just the expression.
For example things like "=1+A1" or "=A1*B1"
Right now it changes the cells even with Paste Special!

See Help for About cell and range references

If you use absolute references, they won't change.

I have a function that does it for a single cell -- I use it when I want to try variations of formulas, and want to make sure that the variation gives the same result.

The reason that Excel doesn't have any method (that I know of) is that people rarely want to see the same thing calculated with the same values in more than one place. Why do you?

You could use a a sub:

Sub FormulaCopy(rInp As Range, rOut As Range)
    ' Copies formula in rInp to rOut without adjustments to references
    rOut.Resize(rInp.Rows.Count, rInp.Columns.Count).Value = rInp.Formula
End Sub

Then from the Immediate window, for example,

FormulaCopy range("B1:B10"), range("D3")

Here are the functions I use to copy a single formula:

Sub CopyFormula()
    ' shortcut Ctrl+Shift+C
    Dim oDO     As DataObject

    Set oDO = New DataObject
    oDO.SetText ActiveCell.Formula
    oDO.PutInClipboard
End Sub

Sub PasteFormula()
    ' shortcut Ctrl+Shift+V
    Dim oDO     As DataObject
    Dim cell    As Range

    If TypeName(Selection) <> "Range" Then
        MsgBox "Selection must be a Range!", "PasteFormula"
        Exit Sub
    End If
    
    Set oDO = New DataObject
    
    On Error Resume Next
    oDO.GetFromClipboard
    
    For Each cell In Selection
        cell.Formula = oDO.GetText
    Next cell
End Sub

You need a set a reference to Microsoft Forms Object Library.

If you're copying array formulas, you have to remake them as array formulas -- I never had occasion to need to do so, so the code doesn't.