Insert Pay Rate Based On Employee Selected

I have a pretty basic spreadsheet set up to calculate payroll for some of our temporary workers. I have a table of workers names and their pay rates in the lower right hand side of my worksheet.

Up until now I have been glancing over to determining their pay rate and manually entering that rate into a specific cell (I2) to start the pay calculations. What I would like to do is somehow add another column to the left of their names and place an "x" or something in that column for the specific employee I am calculating. Once the "x" is placed there I would conditionally format the employees name to be highlighted and have their wage entered into cell I2.

So what I need is a formula to enter into cell I2 which searches cells K5:K24 and when it finds an "x" it enters the payrol rate from the corresponding cell in the range of N5:N24

I know I could revamp my spreadsheet and make a drop down list of names and when a name is selected do a vlookup for the pay rate, but I am looking for a different and hopefully simpler solution.

Thanks, Spence

You don't need to do the "x" thing. This is a standard VLOOKUP calculation. The "x" thing wouldn't work because each "x" would cause something different to happen.

And doing it with a macro doesn't fit my idea of "simpler", so I'd stay with VLOOKUP. It's what it's designed for.

Names = column M
Pay rates = column N

Let's assume you just put a name in cell H2, to get the pay rate to appear on its own in I2, use this:

=VLOOKUP(H2,$M$5:$N$24,2,FALSE)

...and copy that formula down for the rest of the names you add.

If names aren't always in the cell already, use this version to avoid error messages for blanks:

=IF(H2<>"",VLOOKUP(H2,$M$5:$N$24,2,FALSE),"")

If the I2 is being used to only calculate one employee and when you're done, you copy that off somewhere and do another employee in the same spot, then how about this to match closer to your original request:

To get the name to appear on its own in H2:

=INDEX($M$5:$M$24,MATCH("x",$K$5:$K$24,0))

To get the pay rate in I2, same idea:

=INDEX($N$5:$N$24,MATCH("x",$K$5:$K$24,0))

If more than one X is in column K, you might get weird results.

The "x" is what you specified. You could replace that with a cell reference and whatever value is in that cell will be matched instead of Xs. You could use a radio button to control the content of that cell.

=INDEX($M$5:$M$24,MATCH($A$1,$K$5:$K$24,0))

INDEX(MATCH() is a standard technique. Read up on it here:
http://www.contextures.com/xlFunctions03.html