formula is too long

Hello

Can any one please help me in this,how can in compress the following formula

=IF(B3="Monthly",IF(B25="Windows 2003 Std",15,IF(B25="Windows 2003 Ent",30,IF(B25="Windows 2008 Data Center ",40,IF(B25="RHEL 5","30",IF(B25="Windows 2008 Web","15",0))))))+(IF(B3="Quarterly",IF(B25="Windows 2003 Std",40,IF(B25="Windows 2003 Ent",75,IF(B25="RHEL 5","89",IF(B25="Windows 2008 Data Center ",120,IF(B25="Windows 2008 Web","45",0))))))+(IF(B3="Semi-Annually",IF(B25="Windows 2003 Std",75,IF(B25="Windows 2003 Ent",140,IF(B25="Windows 2008 Data Center ",200,IF(B25="RHEL 5","149",IF(B25="Windows 2008 Web","90",0)))))))+(IF(B3="Annually",IF(B25="Windows 2003 Std",150,IF(B25="Windows 2003 Ent",300,IF(B25="RHEL 5","299",IF(B25="Windows 2008 Data Center ",400,IF(B25="Windows 2008 Web","180",0))))))))

Thanks
Rahul

Something like this:

First set up table on the side that lists the possibilities for B5 and tabulate the corresponding numbers in the next 4 columns.

Then assuming you put this table in V1:Z100 use formula

=IF(B3="Monthly",Vlookup(B25,V1:Z100,2,FALSE),0)+IF(B3="Quarterly",Vlookup(B25,V1:Z100,3,False),0)+IF(B3="Semi-Annually",Vlookup(B25,V1:Z100,3,False),0)+IF(B3="Annually",Vlookup(B25,V1:Z100,4,False),0)

adjust the ranges to suit your data

I attached an approach that I would recommend.
It involves setting up this lookup table in F1:J6

Version	                  Monthly  Quarterly  Semiannually  Annually
Windows 2003 Std          15        40         75           150
Windows 2003 Ent          30        75        140           300
Windows 2008 Data Center  40       120        200           400
Windows 2008 Web          15        45         90           180
RHEL 5                    30        89        149           299

Then using this formula

=VLOOKUP(B25,$F$2:$J$6,MATCH(B3,$F$1:$J$1,0),0)

Does that help?

I attached an edited version of your workbook that demonstates the
proper lookup table structure and formulas for the Configuration section.

Lookup table:

Config       Monthly     Quarterly   Semiannually  Annually
2GB          10          30          50            100
4gb          30          90          150           300
8gb          Na          Na          Na            Na
12gb         NA          NA          NA            NA
16gb         NA          NA          NA            NA
18GB         NA          NA          NA            NA

Formula for

E5: =VLOOKUP(B5,$F$1:$J$7,MATCH($B$3,$F$1:$J$1,0),0)

You'll need to create similar tables and formulas for each of the other sections.

I hope that helps.