Links to password protected workbooks

I have a workbook that has links from many other workbooks. They all feed from workbooks that are password protected to open. I need a macro or some way of not having to put all the passwords in everytime I open and update my main workbook. All of the passwords are the same. Any suggestions? Thanks.

How about just having another workbook that opens your workbook with the links
updated/not updated the way you want. Then the code continues to open the other
workbooks.

Saved from a previous post:

Option Explicit
Sub testme()

Dim myFileNames As Variant
Dim myPasswords As Variant
Dim iCtr As Long
Dim myRealWkbk As Workbook
Dim myRealWkbkName As String
Dim wkbk As Workbook

myRealWkbkName = "C:\my documents\excel\book1.xls"

myFileNames = Array("C:\my documents\excel\book11.xls", _
"C:\my documents\excel\book21.xls", _
"C:\my other folder\book11.xls")

myPasswords = Array("pwd1", _
"pwd2", _
"pwd3")

If UBound(myFileNames) <> UBound(myPasswords) Then
MsgBox "check names & passwords--qty mismatch!"
Exit Sub
End If

Set myRealWkbk = Workbooks.Open(Filename:=myRealWkbkName, UpdateLinks:=0)

For iCtr = LBound(myFileNames) To UBound(myFileNames)
Set wkbk = Nothing
On Error Resume Next
Set wkbk = Workbooks.Open(Filename:=myFileNames(iCtr), _
Password:=myPasswords(iCtr))
On Error GoTo 0

If wkbk Is Nothing Then
MsgBox "Check file: " & myFileNames(iCtr)
Exit Sub
End If

wkbk.Close savechanges:=False
Next iCtr

End Sub

(I got bored after 3 workbooks. You may want to test it with a couple to get it
going.)

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm

Nesta777 wrote:
>
> I have a workbook that has links from many other workbooks. They all
> feed from workbooks that are password protected to open. I need a
> macro or some way of not having to put all the passwords in everytime I
> open and update my main workbook. All of the passwords are the same.
> Any suggestions? Thanks.
>
> --
> Nesta777
> ------------------------------------------------------------------------
> Nesta777's Profile: http://www.excelforum.com/member.php...o&userid=36412
> View this thread: http://www.excelforum.com/showthread...hreadid=562716

--

Dave Peterson