Formula not working -- =SUMIF($F$6:$F$91,">=90",G6:I91)

This formula was designed for the following purpose, if data in column/row
F6-F91 are greater than or equal to 90 then sum all amounts in G6 thru I91
(that correspond with the equal/greater to 90.

What is being returned is only the sum of column G6-G91 only, so even though
the criteria is met for say F6 thru F25 I am getting only the sum of G6 thru
G25 and need the sum of G6:I25.

I hope this makes sense. Any help would be appreciated

Use this array formula.


=SUM(IF($F$6:$F$91>=90,$G$6:$I$91,0))

Commit with Ctrl-Shift-Enter rather than enter after typing in the formula. It will result in curly brackets around your formula like,

{=SUM(IF($F$2:$F$8>=90,$G$2:$I$8,0))}

HTH

Steve

SUMIF will only sum up one column or row, try this:

=SUMPRODUCT(($F$6:$F$91>=90)*($G$6:$I$91))


Does that help?

***********
Regards,
Ron

XL2002, WinXP-Pro


"Lucifer" wrote:

> This formula was designed for the following purpose, if data in column/row
> F6-F91 are greater than or equal to 90 then sum all amounts in G6 thru I91
> (that correspond with the equal/greater to 90.
>
> What is being returned is only the sum of column G6-G91 only, so even though
> the criteria is met for say F6 thru F25 I am getting only the sum of G6 thru
> G25 and need the sum of G6:I25.
>
> I hope this makes sense. Any help would be appreciated

You could write an array formula, but that can be annoying if other people
are going to use the worksheet who don't know how to work with arrays. So,
you can try adding two sumif functions:

=SUMIF(G6:G91,">90",H6:H91)+SUMIF(G6:G91,">90",I6:I91)Hope that helps.
--
ERR229


"Lucifer" wrote:

> This formula was designed for the following purpose, if data in column/row
> F6-F91 are greater than or equal to 90 then sum all amounts in G6 thru I91
> (that correspond with the equal/greater to 90.
>
> What is being returned is only the sum of column G6-G91 only, so even though
> the criteria is met for say F6 thru F25 I am getting only the sum of G6 thru
> G25 and need the sum of G6:I25.
>
> I hope this makes sense. Any help would be appreciated

Sumproduct is definitely the way to go ... BUT ... this *does* make Sumif()
total more then one column:

=SUM(SUMIF(F6:F91,">=90",INDIRECT({"G6:G91","H6:H91","I6:I91"})))

--

Regards,

RD
----------------------------------------------------------------------------
-------------------
Please keep all correspondence within the Group, so all may benefit !
----------------------------------------------------------------------------
-------------------

"Ron Coderre" <ronSKIPTHIScoderre@bigfoot.com> wrote in message
news:64FDA034-302F-484D-B58D-61300FB3196D@microsoft.com...
SUMIF will only sum up one column or row, try this:

=SUMPRODUCT(($F$6:$F$91>=90)*($G$6:$I$91))


Does that help?

***********
Regards,
Ron

XL2002, WinXP-Pro


"Lucifer" wrote:

> This formula was designed for the following purpose, if data in column/row
> F6-F91 are greater than or equal to 90 then sum all amounts in G6 thru I91
> (that correspond with the equal/greater to 90.
>
> What is being returned is only the sum of column G6-G91 only, so even
though
> the criteria is met for say F6 thru F25 I am getting only the sum of G6
thru
> G25 and need the sum of G6:I25.
>
> I hope this makes sense. Any help would be appreciated

Ron, thank you for your help. I tried to rate your post but did not know how
to do so. Instructions said it would be at the top or bottom of your post
window but I did not see anything.

Your post as well as the others are really helpful. Thank you.



"Ron Coderre" wrote:

> SUMIF will only sum up one column or row, try this:
>
> =SUMPRODUCT(($F$6:$F$91>=90)*($G$6:$I$91))
>
>
> Does that help?
>
> ***********
> Regards,
> Ron
>
> XL2002, WinXP-Pro
>
>
> "Lucifer" wrote:
>
> > This formula was designed for the following purpose, if data in column/row
> > F6-F91 are greater than or equal to 90 then sum all amounts in G6 thru I91
> > (that correspond with the equal/greater to 90.
> >
> > What is being returned is only the sum of column G6-G91 only, so even though
> > the criteria is met for say F6 thru F25 I am getting only the sum of G6 thru
> > G25 and need the sum of G6:I25.
> >
> > I hope this makes sense. Any help would be appreciated