Add Unique Items w/ Multi Criteria

[mfx_krypt]

I am trying to add up a list of items with multiple criteria. Here is an example piece of data

NAME:..........PROB1:............PROB2:.............SEVERE:
Bob..................X......................X.....................YES
Bob..................X.............................................YES
Charles....................................X.....................YES
Charles...........................................................YES
Charles............X......................X
Keith................X......................X
Keith................X.............................................YES
Keith................X......................X.....................YES
Keith................X

I would like to count the number of times a Unique Name has Prob1 with value "X" and Severe with value "YES" (all three must be true for the row to count). Using this criteria the correct answer for this data is 2.

I have this equation for calculating the number of unique names in the list: =SUMPRODUCT((IF(FREQUENCY(IF(LEN(A2:A1000)>0,MATCH(A2:A1000,A2:A1000,0),""),
IF(LEN(A2:A1000)>0,MATCH(A2:A1000,A2:A1000,0),""))>0,1))

And I have attempted to modify it to meet my criteria like this: =SUMPRODUCT((IF(FREQUENCY(IF(LEN(A2:A1000)>0,MATCH(A2:A1000,A2:A1000,0),""),
IF(LEN(A2:A1000)>0,MATCH(A2:A1000,A2:A1000,0),""))>0,1))*(B2:B1000="X")*(D2:D1000="YES"))

Obviously this equation is returning an error (#N/A) and I cannot figure out the correct way to implement this. I would greatly appreciate it if anyone could help me out with this. Thanks, Keith

[Domenic]

Try the following...

=SUM(IF(FREQUENCY(IF((LEN(A2:A10)>0)*(B2:B10="X")*(D2:D10="Yes"),MATCH(A2:A10,A2:A10,0)),ROW(INDIRECT("1:"&ROWS(A2:A10))))>0,1,0))

OR

=COUNT(1/FREQUENCY(IF((LEN(A2:A10)>0)*(B2:B10="X")*(D2:D10="Yes"),MATCH(A2:A10,A2:A10,0)),ROW(INDIRECT("1:"&ROWS(A2:A10)))))

Both these formulas need to be confirmed with CONTROL+SHIFT+ENTER, not just ENTER.

Hope this helps!

[mfx_krypt]

Wow, very nice. Thank you that is exactly what I needed. I am going to have to put some study time into these commands.

Thanks Again