Importing Data from a text file

A VBA solution is given below where ADO and SQL used.

The important point is, file name should not involve "." so I renamed the file as NQ 03-06_Last.txt

Both the Excel file and the text file must be in the same folder.

Sub Test()
    Dim objConn As Object, RS As Object
    Dim myFile As String, FileNum As Long, strSQL As String
    
    Const adOpenForwardOnly = 0
    Const adLockReadOnly = 1
    Const adCmdText = 1
    Const adUseClient = 3
    
    myFile = ThisWorkbook.Path & "\NQ 03-06_Last.txt"
    
    FileNum = FreeFile
    Open ThisWorkbook.Path & "\Schema.ini" For Output As #FileNum
        Print #FileNum, "[" & Dir(myFile) & "]"
        Print #FileNum, "Format=TabDelimited"
        Print #FileNum, "DateTimeFormat=dd.mm.yyyy"
        Print #FileNum, "ColNameHeader=False"
        Print #FileNum, "DecimalSymbol=."
        Print #FileNum, "TextDelimiter=None"
        Print #FileNum, "Col1=F1 DateTime"
        Print #FileNum, "Col2=F2 Long"
        Print #FileNum, "Col3=F3 Double"
        Print #FileNum, "Col4=F4 Double"
        Print #FileNum, "Col5=F5 Double"
        Print #FileNum, "Col6=F6 Double"
        Print #FileNum, "Col7=F7 Double"
    Close #FileNum
    
    Set objConn = CreateObject("ADODB.Connection")
    Set RS = CreateObject("ADODB.Recordset")
    
    #If Win64 Then
        objConn.Open "Driver=Microsoft Access Text Driver (*.txt, *.csv);" & _
                     "Dbq=" & ThisWorkbook.Path & ";Extensions=asc,csv,tab,txt;"
    #Else
        objConn.Open "Driver={Microsoft Text Driver (*.txt; *.csv)};" & _
                     "Dbq=" & ThisWorkbook.Path & ";Extensions=asc,csv,tab,txt;"
    #End If
    
    strSQL = "Select * From [" & Dir(myFile) & "]"
    RS.Open strSQL, objConn, adUseClient, adLockReadOnly, adCmdText
    
    Range("A2:G" & Rows.Count) = ""
    Range("A2").CopyFromRecordset RS
    
    Range("B2:B" & RS.RecordCount + 1).NumberFormat = "##"":""##"":""##"
    Kill ThisWorkbook.Path & "\Schema.ini"
    
    Set RS = Nothing
    objConn.Close
    Set objConn = Nothing
End Sub

Output is;